git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  10
  11   import Ecto.Changeset
  12   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13
  14   @primary_key false
  15
  16   embedded_schema do
  17     quote do
  18       unquote do
  19         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  20         message_fields()
  21         activity_fields()
  22       end
  23     end
  24
  25     field(:context, :string)
  26     field(:content, :string)
  27   end
  28
  29   def cast_and_validate(data) do
  30     data
  31     |> cast_data()
  32     |> validate_data()
  33   end
  34
  35   def cast_data(data) do
  36     data =
  37       data
  38       |> fix()
  39
  40     %__MODULE__{}
  41     |> changeset(data)
  42   end
  43
  44   def changeset(struct, data) do
  45     struct
  46     |> cast(data, __schema__(:fields))
  47   end
  48
  49   defp fix(data) do
  50     data =
  51       data
  52       |> CommonFixes.fix_actor()
  53       |> CommonFixes.fix_activity_addressing()
  54
  55     with %Object{} = object <- Object.normalize(data["object"]) do
  56       data
  57       |> CommonFixes.fix_activity_context(object)
  58       |> CommonFixes.fix_object_action_recipients(object)
  59     else
  60       _ -> data
  61     end
  62   end
  63
  64   defp validate_emoji(cng) do
  65     content = get_field(cng, :content)
  66
  67     if Pleroma.Emoji.is_unicode_emoji?(content) do
  68       cng
  69     else
  70       cng
  71       |> add_error(:content, "must be a single character emoji")
  72     end
  73   end
  74
  75   defp validate_data(data_cng) do
  76     data_cng
  77     |> validate_inclusion(:type, ["EmojiReact"])
  78     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
  79     |> validate_actor_presence()
  80     |> validate_object_presence()
  81     |> validate_emoji()
  82   end
  83 end