git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Emoji
   9   alias Pleroma.Object
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     quote do
  19       unquote do
  20         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  21         message_fields()
  22         activity_fields()
  23         tag_fields()
  24       end
  25     end
  26
  27     field(:context, :string)
  28     field(:content, :string)
  29   end
  30
  31   def cast_and_validate(data) do
  32     data
  33     |> cast_data()
  34     |> validate_data()
  35   end
  36
  37   def cast_data(data) do
  38     data =
  39       data
  40       |> fix()
  41
  42     %__MODULE__{}
  43     |> changeset(data)
  44   end
  45
  46   def changeset(struct, data) do
  47     struct
  48     |> cast(data, __schema__(:fields) -- [:tag])
  49     |> cast_embed(:tag)
  50   end
  51
  52   defp fix(data) do
  53     data =
  54       data
  55       |> fix_emoji_qualification()
  56       |> CommonFixes.fix_actor()
  57       |> CommonFixes.fix_activity_addressing()
  58
  59     data =
  60       if Map.has_key?(data, "tag") do
  61         data
  62       else
  63         Map.put(data, "tag", [])
  64       end
  65
  66     case Object.normalize(data["object"]) do
  67       %Object{} = object ->
  68         data
  69         |> CommonFixes.fix_activity_context(object)
  70         |> CommonFixes.fix_object_action_recipients(object)
  71
  72       _ ->
  73         data
  74     end
  75   end
  76
  77   defp fix_emoji_qualification(%{"content" => emoji} = data) do
  78     new_emoji = Pleroma.Emoji.fully_qualify_emoji(emoji)
  79
  80     cond do
  81       Pleroma.Emoji.is_unicode_emoji?(emoji) ->
  82         data
  83
  84       Pleroma.Emoji.is_unicode_emoji?(new_emoji) ->
  85         data |> Map.put("content", new_emoji)
  86
  87       true ->
  88         data
  89     end
  90   end
  91
  92   defp fix_emoji_qualification(data), do: data
  93
  94   defp validate_emoji(cng) do
  95     content = get_field(cng, :content)
  96
  97     if Emoji.is_unicode_emoji?(content) || Emoji.matches_shortcode?(content) do
  98       cng
  99     else
 100       cng
 101       |> add_error(:content, "is not a valid emoji")
 102     end
 103   end
 104
 105   defp maybe_validate_tag_presence(cng) do
 106     content = get_field(cng, :content)
 107
 108     if Emoji.is_unicode_emoji?(content) do
 109       cng
 110     else
 111       tag = get_field(cng, :tag)
 112       emoji_name = Emoji.stripped_name(content)
 113
 114       case tag do
 115         [%{name: ^emoji_name, type: "Emoji", icon: %{url: _}}] ->
 116           cng
 117
 118         _ ->
 119           cng
 120           |> add_error(:tag, "does not contain an Emoji tag")
 121       end
 122     end
 123   end
 124
 125   defp validate_data(data_cng) do
 126     data_cng
 127     |> validate_inclusion(:type, ["EmojiReact"])
 128     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
 129     |> validate_actor_presence()
 130     |> validate_object_presence()
 131     |> validate_emoji()
 132     |> maybe_validate_tag_presence()
 133   end
 134 end