git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Emoji
   9   alias Pleroma.Object
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16   @emoji_regex ~r/:[A-Za-z0-9_-]+:/
  17
  18   embedded_schema do
  19     quote do
  20       unquote do
  21         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  22         message_fields()
  23         activity_fields()
  24         tag_fields()
  25       end
  26     end
  27
  28     field(:context, :string)
  29     field(:content, :string)
  30   end
  31
  32   def cast_and_validate(data) do
  33     data
  34     |> cast_data()
  35     |> validate_data()
  36   end
  37
  38   def cast_data(data) do
  39     data =
  40       data
  41       |> fix()
  42
  43     %__MODULE__{}
  44     |> changeset(data)
  45   end
  46
  47   def changeset(struct, data) do
  48     struct
  49     |> cast(data, __schema__(:fields) -- [:tag])
  50     |> cast_embed(:tag)
  51   end
  52
  53   defp fix(data) do
  54     data =
  55       data
  56       |> fix_emoji_qualification()
  57       |> CommonFixes.fix_actor()
  58       |> CommonFixes.fix_activity_addressing()
  59
  60     data =
  61       if Map.has_key?(data, "tag") do
  62         data
  63       else
  64         Map.put(data, "tag", [])
  65       end
  66
  67     case Object.normalize(data["object"]) do
  68       %Object{} = object ->
  69         data
  70         |> CommonFixes.fix_activity_context(object)
  71         |> CommonFixes.fix_object_action_recipients(object)
  72
  73       _ ->
  74         data
  75     end
  76   end
  77
  78   defp matches_shortcode?(nil), do: false
  79   defp matches_shortcode?(s), do: Regex.match?(@emoji_regex, s)
  80
  81   defp fix_emoji_qualification(%{"content" => emoji} = data) do
  82     new_emoji = Pleroma.Emoji.fully_qualify_emoji(emoji)
  83
  84     cond do
  85       Pleroma.Emoji.is_unicode_emoji?(emoji) ->
  86         data
  87
  88       Pleroma.Emoji.is_unicode_emoji?(new_emoji) ->
  89         data |> Map.put("content", new_emoji)
  90
  91       true ->
  92         data
  93     end
  94   end
  95
  96   defp fix_emoji_qualification(data), do: data
  97
  98   defp validate_emoji(cng) do
  99     content = get_field(cng, :content)
 100
 101     if Emoji.is_unicode_emoji?(content) || matches_shortcode?(content) do
 102       cng
 103     else
 104       cng
 105       |> add_error(:content, "is not a valid emoji")
 106     end
 107   end
 108
 109   defp maybe_validate_tag_presence(cng) do
 110     content = get_field(cng, :content)
 111
 112     if Emoji.is_unicode_emoji?(content) do
 113       cng
 114     else
 115       tag = get_field(cng, :tag)
 116       emoji_name = Emoji.stripped_name(content)
 117
 118       case tag do
 119         [%{name: ^emoji_name, type: "Emoji", icon: %{url: _}}] ->
 120           cng
 121
 122         _ ->
 123           cng
 124           |> add_error(:tag, "does not contain an Emoji tag")
 125       end
 126     end
 127   end
 128
 129   defp validate_data(data_cng) do
 130     data_cng
 131     |> validate_inclusion(:type, ["EmojiReact"])
 132     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
 133     |> validate_actor_presence()
 134     |> validate_object_presence()
 135     |> validate_emoji()
 136     |> maybe_validate_tag_presence()
 137   end
 138 end