git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/delete_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, Types.ObjectID, primary_key: true)
  19     field(:type, :string)
  20     field(:actor, Types.ObjectID)
  21     field(:to, Types.Recipients, default: [])
  22     field(:cc, Types.Recipients, default: [])
  23     field(:deleted_activity_id, Types.ObjectID)
  24     field(:object, Types.ObjectID)
  25   end
  26
  27   def cast_data(data) do
  28     %__MODULE__{}
  29     |> cast(data, __schema__(:fields))
  30   end
  31
  32   def add_deleted_activity_id(cng) do
  33     object =
  34       cng
  35       |> get_field(:object)
  36
  37     with %Activity{id: id} <- Activity.get_create_by_object_ap_id(object) do
  38       cng
  39       |> put_change(:deleted_activity_id, id)
  40     else
  41       _ -> cng
  42     end
  43   end
  44
  45   @deletable_types ~w{
  46     Answer
  47     Article
  48     Audio
  49     Event
  50     Note
  51     Page
  52     Question
  53     Video
  54   }
  55   def validate_data(cng) do
  56     cng
  57     |> validate_required([:id, :type, :actor, :to, :cc, :object])
  58     |> validate_inclusion(:type, ["Delete"])
  59     |> validate_actor_presence()
  60     |> validate_deletion_rights()
  61     |> validate_object_or_user_presence(allowed_types: @deletable_types)
  62     |> add_deleted_activity_id()
  63   end
  64
  65   def do_not_federate?(cng) do
  66     !same_domain?(cng)
  67   end
  68
  69   defp same_domain?(cng) do
  70     actor_uri =
  71       cng
  72       |> get_field(:actor)
  73       |> URI.parse()
  74
  75     object_uri =
  76       cng
  77       |> get_field(:object)
  78       |> URI.parse()
  79
  80     object_uri.host == actor_uri.host
  81   end
  82
  83   def validate_deletion_rights(cng) do
  84     actor = User.get_cached_by_ap_id(get_field(cng, :actor))
  85
  86     if User.superuser?(actor) || same_domain?(cng) do
  87       cng
  88     else
  89       cng
  90       |> add_error(:actor, "is not allowed to delete object")
  91     end
  92   end
  93
  94   def cast_and_validate(data) do
  95     data
  96     |> cast_data
  97     |> validate_data
  98   end
  99 end