git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/delete_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, Types.ObjectID, primary_key: true)
  19     field(:type, :string)
  20     field(:actor, Types.ObjectID)
  21     field(:to, Types.Recipients, default: [])
  22     field(:cc, Types.Recipients, default: [])
  23     field(:deleted_activity_id, Types.ObjectID)
  24     field(:object, Types.ObjectID)
  25   end
  26
  27   def cast_data(data) do
  28     %__MODULE__{}
  29     |> cast(data, __schema__(:fields))
  30   end
  31
  32   def add_deleted_activity_id(cng) do
  33     object =
  34       cng
  35       |> get_field(:object)
  36
  37     with %Activity{id: id} <- Activity.get_create_by_object_ap_id(object) do
  38       cng
  39       |> put_change(:deleted_activity_id, id)
  40     else
  41       _ -> cng
  42     end
  43   end
  44
  45   @deletable_types ~w{
  46     Answer
  47     Article
  48     Audio
  49     Event
  50     Note
  51     Page
  52     Question
  53     Video
  54     Tombstone
  55   }
  56   def validate_data(cng) do
  57     cng
  58     |> validate_required([:id, :type, :actor, :to, :cc, :object])
  59     |> validate_inclusion(:type, ["Delete"])
  60     |> validate_actor_presence()
  61     |> validate_deletion_rights()
  62     |> validate_object_or_user_presence(allowed_types: @deletable_types)
  63     |> add_deleted_activity_id()
  64   end
  65
  66   def do_not_federate?(cng) do
  67     !same_domain?(cng)
  68   end
  69
  70   defp same_domain?(cng) do
  71     actor_uri =
  72       cng
  73       |> get_field(:actor)
  74       |> URI.parse()
  75
  76     object_uri =
  77       cng
  78       |> get_field(:object)
  79       |> URI.parse()
  80
  81     object_uri.host == actor_uri.host
  82   end
  83
  84   def validate_deletion_rights(cng) do
  85     actor = User.get_cached_by_ap_id(get_field(cng, :actor))
  86
  87     if User.superuser?(actor) || same_domain?(cng) do
  88       cng
  89     else
  90       cng
  91       |> add_error(:actor, "is not allowed to delete object")
  92     end
  93   end
  94
  95   def cast_and_validate(data) do
  96     data
  97     |> cast_data
  98     |> validate_data
  99   end
 100 end