git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/delete_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  10   alias Pleroma.User
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, ObjectValidators.ObjectID, primary_key: true)
  19     field(:type, :string)
  20     field(:actor, ObjectValidators.ObjectID)
  21     field(:to, ObjectValidators.Recipients, default: [])
  22     field(:cc, ObjectValidators.Recipients, default: [])
  23     field(:deleted_activity_id, ObjectValidators.ObjectID)
  24     field(:object, ObjectValidators.ObjectID)
  25   end
  26
  27   def cast_data(data) do
  28     %__MODULE__{}
  29     |> cast(data, __schema__(:fields))
  30   end
  31
  32   def add_deleted_activity_id(cng) do
  33     object =
  34       cng
  35       |> get_field(:object)
  36
  37     with %Activity{id: id} <- Activity.get_create_by_object_ap_id(object) do
  38       cng
  39       |> put_change(:deleted_activity_id, id)
  40     else
  41       _ -> cng
  42     end
  43   end
  44
  45   @deletable_types ~w{
  46     Answer
  47     Article
  48     Audio
  49     ChatMessage
  50     Event
  51     Note
  52     Page
  53     Question
  54     Tombstone
  55     Video
  56   }
  57   def validate_data(cng) do
  58     cng
  59     |> validate_required([:id, :type, :actor, :to, :cc, :object])
  60     |> validate_inclusion(:type, ["Delete"])
  61     |> validate_actor_presence()
  62     |> validate_deletion_rights()
  63     |> validate_object_or_user_presence(allowed_types: @deletable_types)
  64     |> add_deleted_activity_id()
  65   end
  66
  67   def do_not_federate?(cng) do
  68     !same_domain?(cng)
  69   end
  70
  71   defp same_domain?(cng) do
  72     actor_uri =
  73       cng
  74       |> get_field(:actor)
  75       |> URI.parse()
  76
  77     object_uri =
  78       cng
  79       |> get_field(:object)
  80       |> URI.parse()
  81
  82     object_uri.host == actor_uri.host
  83   end
  84
  85   def validate_deletion_rights(cng) do
  86     actor = User.get_cached_by_ap_id(get_field(cng, :actor))
  87
  88     if User.superuser?(actor) || same_domain?(cng) do
  89       cng
  90     else
  91       cng
  92       |> add_error(:actor, "is not allowed to delete object")
  93     end
  94   end
  95
  96   def cast_and_validate(data) do
  97     data
  98     |> cast_data
  99     |> validate_data
 100   end
 101 end