git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/create_generic_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # Code based on CreateChatMessageValidator
   6 # NOTES
   7 # - doesn't embed, will only get the object id
   8 defmodule Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator do
   9   use Ecto.Schema
  10
  11   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  12   alias Pleroma.Object
  13
  14   import Ecto.Changeset
  15   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  16
  17   @primary_key false
  18
  19   embedded_schema do
  20     field(:id, ObjectValidators.ObjectID, primary_key: true)
  21     field(:actor, ObjectValidators.ObjectID)
  22     field(:type, :string)
  23     field(:to, ObjectValidators.Recipients, default: [])
  24     field(:cc, ObjectValidators.Recipients, default: [])
  25     field(:object, ObjectValidators.ObjectID)
  26     field(:expires_at, ObjectValidators.DateTime)
  27
  28     # Should be moved to object, done for CommonAPI.Utils.make_context
  29     field(:context, :string)
  30   end
  31
  32   def cast_data(data, meta \\ []) do
  33     data = fix(data, meta)
  34
  35     %__MODULE__{}
  36     |> changeset(data)
  37   end
  38
  39   def cast_and_apply(data) do
  40     data
  41     |> cast_data
  42     |> apply_action(:insert)
  43   end
  44
  45   def cast_and_validate(data, meta \\ []) do
  46     data
  47     |> cast_data(meta)
  48     |> validate_data(meta)
  49   end
  50
  51   def changeset(struct, data) do
  52     struct
  53     |> cast(data, __schema__(:fields))
  54   end
  55
  56   defp fix_context(data, meta) do
  57     if object = meta[:object_data] do
  58       Map.put_new(data, "context", object["context"])
  59     else
  60       data
  61     end
  62   end
  63
  64   defp fix_addressing(data, meta) do
  65     if object = meta[:object_data] do
  66       data
  67       |> Map.put_new("to", object["to"] || [])
  68       |> Map.put_new("cc", object["cc"] || [])
  69     else
  70       data
  71     end
  72   end
  73
  74   defp fix(data, meta) do
  75     data
  76     |> fix_context(meta)
  77     |> fix_addressing(meta)
  78   end
  79
  80   def validate_data(cng, meta \\ []) do
  81     cng
  82     |> validate_required([:actor, :type, :object])
  83     |> validate_inclusion(:type, ["Create"])
  84     |> validate_actor_presence()
  85     |> validate_any_presence([:to, :cc])
  86     |> validate_actors_match(meta)
  87     |> validate_context_match(meta)
  88     |> validate_object_nonexistence()
  89     |> validate_object_containment()
  90   end
  91
  92   def validate_object_containment(cng) do
  93     actor = get_field(cng, :actor)
  94
  95     cng
  96     |> validate_change(:object, fn :object, object_id ->
  97       %URI{host: object_id_host} = URI.parse(object_id)
  98       %URI{host: actor_host} = URI.parse(actor)
  99
 100       if object_id_host == actor_host do
 101         []
 102       else
 103         [{:object, "The host of the object id doesn't match with the host of the actor"}]
 104       end
 105     end)
 106   end
 107
 108   def validate_object_nonexistence(cng) do
 109     cng
 110     |> validate_change(:object, fn :object, object_id ->
 111       if Object.get_cached_by_ap_id(object_id) do
 112         [{:object, "The object to create already exists"}]
 113       else
 114         []
 115       end
 116     end)
 117   end
 118
 119   def validate_actors_match(cng, meta) do
 120     attributed_to = meta[:object_data]["attributedTo"] || meta[:object_data]["actor"]
 121
 122     cng
 123     |> validate_change(:actor, fn :actor, actor ->
 124       if actor == attributed_to do
 125         []
 126       else
 127         [{:actor, "Actor doesn't match with object attributedTo"}]
 128       end
 129     end)
 130   end
 131
 132   def validate_context_match(cng, %{object_data: %{"context" => object_context}}) do
 133     cng
 134     |> validate_change(:context, fn :context, context ->
 135       if context == object_context do
 136         []
 137       else
 138         [{:context, "context field not matching between Create and object (#{object_context})"}]
 139       end
 140     end)
 141   end
 142
 143   def validate_context_match(cng, _), do: cng
 144 end