git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/create_chat_message_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # NOTES
   6 # - Can probably be a generic create validator
   7 # - doesn't embed, will only get the object id
   8 defmodule Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator do
   9   use Ecto.Schema
  10
  11   alias Pleroma.Object
  12   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  13
  14   import Ecto.Changeset
  15   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  16
  17   @primary_key false
  18
  19   embedded_schema do
  20     field(:id, Types.ObjectID, primary_key: true)
  21     field(:actor, Types.ObjectID)
  22     field(:type, :string)
  23     field(:to, Types.Recipients, default: [])
  24     field(:object, Types.ObjectID)
  25   end
  26
  27   def cast_and_apply(data) do
  28     data
  29     |> cast_data
  30     |> apply_action(:insert)
  31   end
  32
  33   def cast_data(data) do
  34     cast(%__MODULE__{}, data, __schema__(:fields))
  35   end
  36
  37   def cast_and_validate(data, meta \\ []) do
  38     cast_data(data)
  39     |> validate_data(meta)
  40   end
  41
  42   def validate_data(cng, meta \\ []) do
  43     cng
  44     |> validate_required([:id, :actor, :to, :type, :object])
  45     |> validate_inclusion(:type, ["Create"])
  46     |> validate_actor_presence()
  47     |> validate_recipients_match(meta)
  48     |> validate_object_nonexistence()
  49   end
  50
  51   def validate_object_nonexistence(cng) do
  52     cng
  53     |> validate_change(:object, fn :object, object_id ->
  54       if Object.get_cached_by_ap_id(object_id) do
  55         [{:object, "The object to create already exists"}]
  56       else
  57         []
  58       end
  59     end)
  60   end
  61
  62   def validate_recipients_match(cng, meta) do
  63     object_recipients = meta[:object_data]["to"] || []
  64
  65     cng
  66     |> validate_change(:to, fn :to, recipients ->
  67       activity_set = MapSet.new(recipients)
  68       object_set = MapSet.new(object_recipients)
  69
  70       if MapSet.equal?(activity_set, object_set) do
  71         []
  72       else
  73         [{:to, "Recipients don't match with object recipients"}]
  74       end
  75     end)
  76   end
  77 end