git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/create_chat_message_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # NOTES
   6 # - Can probably be a generic create validator
   7 # - doesn't embed, will only get the object id
   8 defmodule Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator do
   9   use Ecto.Schema
  10   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  11
  12   alias Pleroma.Object
  13
  14   import Ecto.Changeset
  15   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  16
  17   @primary_key false
  18
  19   embedded_schema do
  20     field(:id, ObjectValidators.ObjectID, primary_key: true)
  21     field(:actor, ObjectValidators.ObjectID)
  22     field(:type, :string)
  23     field(:to, ObjectValidators.Recipients, default: [])
  24     field(:object, ObjectValidators.ObjectID)
  25   end
  26
  27   def cast_and_apply(data) do
  28     data
  29     |> cast_data
  30     |> apply_action(:insert)
  31   end
  32
  33   def cast_data(data) do
  34     cast(%__MODULE__{}, data, __schema__(:fields))
  35   end
  36
  37   def cast_and_validate(data, meta \\ []) do
  38     cast_data(data)
  39     |> validate_data(meta)
  40   end
  41
  42   defp validate_data(cng, meta) do
  43     cng
  44     |> validate_required([:id, :actor, :to, :type, :object])
  45     |> validate_inclusion(:type, ["Create"])
  46     |> validate_actor_presence()
  47     |> validate_recipients_match(meta)
  48     |> validate_actors_match(meta)
  49     |> validate_object_nonexistence()
  50   end
  51
  52   def validate_object_nonexistence(cng) do
  53     cng
  54     |> validate_change(:object, fn :object, object_id ->
  55       if Object.get_cached_by_ap_id(object_id) do
  56         [{:object, "The object to create already exists"}]
  57       else
  58         []
  59       end
  60     end)
  61   end
  62
  63   def validate_actors_match(cng, meta) do
  64     object_actor = meta[:object_data]["actor"]
  65
  66     cng
  67     |> validate_change(:actor, fn :actor, actor ->
  68       if actor == object_actor do
  69         []
  70       else
  71         [{:actor, "Actor doesn't match with object actor"}]
  72       end
  73     end)
  74   end
  75
  76   def validate_recipients_match(cng, meta) do
  77     object_recipients = meta[:object_data]["to"] || []
  78
  79     cng
  80     |> validate_change(:to, fn :to, recipients ->
  81       activity_set = MapSet.new(recipients)
  82       object_set = MapSet.new(object_recipients)
  83
  84       if MapSet.equal?(activity_set, object_set) do
  85         []
  86       else
  87         [{:to, "Recipients don't match with object recipients"}]
  88       end
  89     end)
  90   end
  91 end