git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/create_chat_message_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # NOTES
   6 # - Can probably be a generic create validator
   7 # - doesn't embed, will only get the object id
   8 defmodule Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator do
   9   use Ecto.Schema
  10   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  11
  12   alias Pleroma.Object
  13
  14   import Ecto.Changeset
  15   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  16
  17   @primary_key false
  18
  19   embedded_schema do
  20     quote do
  21       unquote do
  22         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  23         activity_fields()
  24       end
  25     end
  26
  27     field(:id, ObjectValidators.ObjectID, primary_key: true)
  28     field(:type, :string)
  29     field(:to, ObjectValidators.Recipients, default: [])
  30   end
  31
  32   def cast_and_apply(data) do
  33     data
  34     |> cast_data
  35     |> apply_action(:insert)
  36   end
  37
  38   def cast_data(data) do
  39     cast(%__MODULE__{}, data, __schema__(:fields))
  40   end
  41
  42   def cast_and_validate(data, meta \\ []) do
  43     cast_data(data)
  44     |> validate_data(meta)
  45   end
  46
  47   defp validate_data(cng, meta) do
  48     cng
  49     |> validate_required([:id, :actor, :to, :type, :object])
  50     |> validate_inclusion(:type, ["Create"])
  51     |> validate_actor_presence()
  52     |> validate_recipients_match(meta)
  53     |> validate_actors_match(meta)
  54     |> validate_object_nonexistence()
  55   end
  56
  57   def validate_object_nonexistence(cng) do
  58     cng
  59     |> validate_change(:object, fn :object, object_id ->
  60       if Object.get_cached_by_ap_id(object_id) do
  61         [{:object, "The object to create already exists"}]
  62       else
  63         []
  64       end
  65     end)
  66   end
  67
  68   def validate_actors_match(cng, meta) do
  69     object_actor = meta[:object_data]["actor"]
  70
  71     cng
  72     |> validate_change(:actor, fn :actor, actor ->
  73       if actor == object_actor do
  74         []
  75       else
  76         [{:actor, "Actor doesn't match with object actor"}]
  77       end
  78     end)
  79   end
  80
  81   def validate_recipients_match(cng, meta) do
  82     object_recipients = meta[:object_data]["to"] || []
  83
  84     cng
  85     |> validate_change(:to, fn :to, recipients ->
  86       activity_set = MapSet.new(recipients)
  87       object_set = MapSet.new(object_recipients)
  88
  89       if MapSet.equal?(activity_set, object_set) do
  90         []
  91       else
  92         [{:to, "Recipients don't match with object recipients"}]
  93       end
  94     end)
  95   end
  96 end