git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/chat_message_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.Transmogrifier, only: [fix_emoji: 1]
  14
  15   @primary_key false
  16   @derive Jason.Encoder
  17
  18   embedded_schema do
  19     field(:id, Types.ObjectID, primary_key: true)
  20     field(:to, Types.Recipients, default: [])
  21     field(:type, :string)
  22     field(:content, Types.SafeText)
  23     field(:actor, Types.ObjectID)
  24     field(:published, Types.DateTime)
  25     field(:emoji, :map, default: %{})
  26
  27     embeds_one(:attachment, AttachmentValidator)
  28   end
  29
  30   def cast_and_apply(data) do
  31     data
  32     |> cast_data
  33     |> apply_action(:insert)
  34   end
  35
  36   def cast_and_validate(data) do
  37     data
  38     |> cast_data()
  39     |> validate_data()
  40   end
  41
  42   def cast_data(data) do
  43     %__MODULE__{}
  44     |> changeset(data)
  45   end
  46
  47   def fix(data) do
  48     data
  49     |> fix_emoji()
  50     |> Map.put_new("actor", data["attributedTo"])
  51   end
  52
  53   def changeset(struct, data) do
  54     data = fix(data)
  55
  56     struct
  57     |> cast(data, List.delete(__schema__(:fields), :attachment))
  58     |> cast_embed(:attachment)
  59   end
  60
  61   def validate_data(data_cng) do
  62     data_cng
  63     |> validate_inclusion(:type, ["ChatMessage"])
  64     |> validate_required([:id, :actor, :to, :type, :content, :published])
  65     |> validate_length(:to, is: 1)
  66     |> validate_length(:content, max: Pleroma.Config.get([:instance, :remote_limit]))
  67     |> validate_local_concern()
  68   end
  69
  70   @doc """
  71   Validates the following
  72   - If both users are in our system
  73   - If at least one of the users in this ChatMessage is a local user
  74   - If the recipient is not blocking the actor
  75   """
  76   def validate_local_concern(cng) do
  77     with actor_ap <- get_field(cng, :actor),
  78          {_, %User{} = actor} <- {:find_actor, User.get_cached_by_ap_id(actor_ap)},
  79          {_, %User{} = recipient} <-
  80            {:find_recipient, User.get_cached_by_ap_id(get_field(cng, :to) |> hd())},
  81          {_, false} <- {:blocking_actor?, User.blocks?(recipient, actor)},
  82          {_, true} <- {:local?, Enum.any?([actor, recipient], & &1.local)} do
  83       cng
  84     else
  85       {:blocking_actor?, true} ->
  86         cng
  87         |> add_error(:actor, "actor is blocked by recipient")
  88
  89       {:local?, false} ->
  90         cng
  91         |> add_error(:actor, "actor and recipient are both remote")
  92
  93       {:find_actor, _} ->
  94         cng
  95         |> add_error(:actor, "can't find user")
  96
  97       {:find_recipient, _} ->
  98         cng
  99         |> add_error(:to, "can't find user")
 100     end
 101   end
 102 end