git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/audio_video_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  12   alias Pleroma.Web.ActivityPub.ObjectValidators.TagValidator
  13   alias Pleroma.Web.ActivityPub.Transmogrifier
  14
  15   import Ecto.Changeset
  16
  17   @primary_key false
  18   @derive Jason.Encoder
  19
  20   embedded_schema do
  21     field(:id, ObjectValidators.ObjectID, primary_key: true)
  22     field(:to, ObjectValidators.Recipients, default: [])
  23     field(:cc, ObjectValidators.Recipients, default: [])
  24     field(:bto, ObjectValidators.Recipients, default: [])
  25     field(:bcc, ObjectValidators.Recipients, default: [])
  26     embeds_many(:tag, TagValidator)
  27     field(:type, :string)
  28
  29     field(:name, :string)
  30     field(:summary, :string)
  31     field(:content, :string)
  32
  33     field(:context, :string)
  34     # short identifier for PleromaFE to group statuses by context
  35     field(:context_id, :integer)
  36
  37     # TODO: Remove actor on objects
  38     field(:actor, ObjectValidators.ObjectID)
  39
  40     field(:attributedTo, ObjectValidators.ObjectID)
  41     field(:published, ObjectValidators.DateTime)
  42     field(:emoji, ObjectValidators.Emoji, default: %{})
  43     field(:sensitive, :boolean, default: false)
  44     embeds_many(:attachment, AttachmentValidator)
  45     field(:replies_count, :integer, default: 0)
  46     field(:like_count, :integer, default: 0)
  47     field(:announcement_count, :integer, default: 0)
  48     field(:inReplyTo, ObjectValidators.ObjectID)
  49     field(:url, ObjectValidators.Uri)
  50
  51     field(:likes, {:array, ObjectValidators.ObjectID}, default: [])
  52     field(:announcements, {:array, ObjectValidators.ObjectID}, default: [])
  53   end
  54
  55   def cast_and_apply(data) do
  56     data
  57     |> cast_data
  58     |> apply_action(:insert)
  59   end
  60
  61   def cast_and_validate(data) do
  62     data
  63     |> cast_data()
  64     |> validate_data()
  65   end
  66
  67   def cast_data(data) do
  68     %__MODULE__{}
  69     |> changeset(data)
  70   end
  71
  72   defp find_attachment(url) do
  73     mpeg_url =
  74       Enum.find(url, fn
  75         %{"mediaType" => mime_type, "tag" => tags} when is_list(tags) ->
  76           mime_type == "application/x-mpegURL"
  77
  78         _ ->
  79           false
  80       end)
  81
  82     url
  83     |> Enum.concat(mpeg_url["tag"] || [])
  84     |> Enum.find(fn
  85       %{"mediaType" => mime_type} -> String.starts_with?(mime_type, ["video/", "audio/"])
  86       %{"mimeType" => mime_type} -> String.starts_with?(mime_type, ["video/", "audio/"])
  87       _ -> false
  88     end)
  89   end
  90
  91   defp fix_url(%{"url" => url} = data) when is_list(url) do
  92     attachment = find_attachment(url)
  93
  94     link_element =
  95       Enum.find(url, fn
  96         %{"mediaType" => "text/html"} -> true
  97         %{"mimeType" => "text/html"} -> true
  98         _ -> false
  99       end)
 100
 101     data
 102     |> Map.put("attachment", [attachment])
 103     |> Map.put("url", link_element["href"])
 104   end
 105
 106   defp fix_url(data), do: data
 107
 108   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = data)
 109        when is_binary(content) do
 110     content =
 111       content
 112       |> Pleroma.Formatter.markdown_to_html()
 113       |> Pleroma.HTML.filter_tags()
 114
 115     Map.put(data, "content", content)
 116   end
 117
 118   defp fix_content(data), do: data
 119
 120   defp fix(data) do
 121     data
 122     |> CommonFixes.fix_actor()
 123     |> CommonFixes.fix_object_defaults()
 124     |> Transmogrifier.fix_emoji()
 125     |> fix_url()
 126     |> fix_content()
 127   end
 128
 129   def changeset(struct, data) do
 130     data = fix(data)
 131
 132     struct
 133     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
 134     |> cast_embed(:attachment)
 135     |> cast_embed(:tag)
 136   end
 137
 138   defp validate_data(data_cng) do
 139     data_cng
 140     |> validate_inclusion(:type, ["Audio", "Video"])
 141     |> validate_required([:id, :actor, :attributedTo, :type, :context, :attachment])
 142     |> CommonValidations.validate_any_presence([:cc, :to])
 143     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 144     |> CommonValidations.validate_actor_presence()
 145     |> CommonValidations.validate_host_match()
 146   end
 147 end