git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/audio_video_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EarmarkRenderer
   9   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  12   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13   alias Pleroma.Web.ActivityPub.Transmogrifier
  14
  15   import Ecto.Changeset
  16
  17   @primary_key false
  18   @derive Jason.Encoder
  19
  20   embedded_schema do
  21     field(:id, ObjectValidators.ObjectID, primary_key: true)
  22     field(:to, ObjectValidators.Recipients, default: [])
  23     field(:cc, ObjectValidators.Recipients, default: [])
  24     field(:bto, ObjectValidators.Recipients, default: [])
  25     field(:bcc, ObjectValidators.Recipients, default: [])
  26     # TODO: Write type
  27     field(:tag, {:array, :map}, default: [])
  28     field(:type, :string)
  29
  30     field(:name, :string)
  31     field(:summary, :string)
  32     field(:content, :string)
  33
  34     field(:context, :string)
  35     # short identifier for PleromaFE to group statuses by context
  36     field(:context_id, :integer)
  37
  38     # TODO: Remove actor on objects
  39     field(:actor, ObjectValidators.ObjectID)
  40
  41     field(:attributedTo, ObjectValidators.ObjectID)
  42     field(:published, ObjectValidators.DateTime)
  43     field(:emoji, ObjectValidators.Emoji, default: %{})
  44     field(:sensitive, :boolean, default: false)
  45     embeds_many(:attachment, AttachmentValidator)
  46     field(:replies_count, :integer, default: 0)
  47     field(:like_count, :integer, default: 0)
  48     field(:announcement_count, :integer, default: 0)
  49     field(:inReplyTo, ObjectValidators.ObjectID)
  50     field(:url, ObjectValidators.Uri)
  51
  52     field(:likes, {:array, ObjectValidators.ObjectID}, default: [])
  53     field(:announcements, {:array, ObjectValidators.ObjectID}, default: [])
  54   end
  55
  56   def cast_and_apply(data) do
  57     data
  58     |> cast_data
  59     |> apply_action(:insert)
  60   end
  61
  62   def cast_and_validate(data) do
  63     data
  64     |> cast_data()
  65     |> validate_data()
  66   end
  67
  68   def cast_data(data) do
  69     %__MODULE__{}
  70     |> changeset(data)
  71   end
  72
  73   defp find_attachment(url) do
  74     mpeg_url =
  75       Enum.find(url, fn
  76         %{"mediaType" => mime_type, "tag" => tags} when is_list(tags) ->
  77           mime_type == "application/x-mpegURL"
  78
  79         _ ->
  80           false
  81       end)
  82
  83     url
  84     |> Enum.concat(mpeg_url["tag"] || [])
  85     |> Enum.find(fn
  86       %{"mediaType" => mime_type} -> String.starts_with?(mime_type, ["video/", "audio/"])
  87       %{"mimeType" => mime_type} -> String.starts_with?(mime_type, ["video/", "audio/"])
  88       _ -> false
  89     end)
  90   end
  91
  92   defp fix_url(%{"url" => url} = data) when is_list(url) do
  93     attachment = find_attachment(url)
  94
  95     link_element =
  96       Enum.find(url, fn
  97         %{"mediaType" => "text/html"} -> true
  98         %{"mimeType" => "text/html"} -> true
  99         _ -> false
 100       end)
 101
 102     data
 103     |> Map.put("attachment", [attachment])
 104     |> Map.put("url", link_element["href"])
 105   end
 106
 107   defp fix_url(data), do: data
 108
 109   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = data)
 110        when is_binary(content) do
 111     content =
 112       content
 113       |> Earmark.as_html!(%Earmark.Options{renderer: EarmarkRenderer})
 114       |> Pleroma.HTML.filter_tags()
 115
 116     Map.put(data, "content", content)
 117   end
 118
 119   defp fix_content(data), do: data
 120
 121   defp fix(data) do
 122     data
 123     |> CommonFixes.fix_defaults()
 124     |> CommonFixes.fix_attribution()
 125     |> CommonFixes.fix_actor()
 126     |> Transmogrifier.fix_emoji()
 127     |> fix_url()
 128     |> fix_content()
 129   end
 130
 131   def changeset(struct, data) do
 132     data = fix(data)
 133
 134     struct
 135     |> cast(data, __schema__(:fields) -- [:attachment])
 136     |> cast_embed(:attachment)
 137   end
 138
 139   def validate_data(data_cng) do
 140     data_cng
 141     |> validate_inclusion(:type, ["Audio", "Video"])
 142     |> validate_required([:id, :actor, :attributedTo, :type, :context, :attachment])
 143     |> CommonValidations.validate_any_presence([:cc, :to])
 144     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 145     |> CommonValidations.validate_actor_presence()
 146     |> CommonValidations.validate_host_match()
 147   end
 148 end