git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/audio_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AudioValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  11   alias Pleroma.Web.ActivityPub.Utils
  12
  13   import Ecto.Changeset
  14
  15   @primary_key false
  16   @derive Jason.Encoder
  17
  18   # Extends from NoteValidator
  19   embedded_schema do
  20     field(:id, ObjectValidators.ObjectID, primary_key: true)
  21     field(:to, ObjectValidators.Recipients, default: [])
  22     field(:cc, ObjectValidators.Recipients, default: [])
  23     field(:bto, ObjectValidators.Recipients, default: [])
  24     field(:bcc, ObjectValidators.Recipients, default: [])
  25     # TODO: Write type
  26     field(:tag, {:array, :map}, default: [])
  27     field(:type, :string)
  28     field(:content, :string)
  29     field(:context, :string)
  30
  31     # TODO: Remove actor on objects
  32     field(:actor, ObjectValidators.ObjectID)
  33
  34     field(:attributedTo, ObjectValidators.ObjectID)
  35     field(:summary, :string)
  36     field(:published, ObjectValidators.DateTime)
  37     # TODO: Write type
  38     field(:emoji, :map, default: %{})
  39     field(:sensitive, :boolean, default: false)
  40     embeds_many(:attachment, AttachmentValidator)
  41     field(:replies_count, :integer, default: 0)
  42     field(:like_count, :integer, default: 0)
  43     field(:announcement_count, :integer, default: 0)
  44     field(:inReplyTo, :string)
  45     field(:uri, ObjectValidators.Uri)
  46     # short identifier for PleromaFE to group statuses by context
  47     field(:context_id, :integer)
  48
  49     field(:likes, {:array, :string}, default: [])
  50     field(:announcements, {:array, :string}, default: [])
  51   end
  52
  53   def cast_and_apply(data) do
  54     data
  55     |> cast_data
  56     |> apply_action(:insert)
  57   end
  58
  59   def cast_and_validate(data) do
  60     data
  61     |> cast_data()
  62     |> validate_data()
  63   end
  64
  65   def cast_data(data) do
  66     %__MODULE__{}
  67     |> changeset(data)
  68   end
  69
  70   # based on Pleroma.Web.ActivityPub.Utils.lazy_put_objects_defaults
  71   defp fix_defaults(data) do
  72     %{data: %{"id" => context}, id: context_id} =
  73       Utils.create_context(data["context"] || data["conversation"])
  74
  75     data
  76     |> Map.put_new_lazy("published", &Utils.make_date/0)
  77     |> Map.put_new("context", context)
  78     |> Map.put_new("context_id", context_id)
  79   end
  80
  81   defp fix_attribution(data) do
  82     data
  83     |> Map.put_new("actor", data["attributedTo"])
  84   end
  85
  86   defp fix(data) do
  87     data
  88     |> fix_defaults()
  89     |> fix_attribution()
  90   end
  91
  92   def changeset(struct, data) do
  93     data = fix(data)
  94
  95     struct
  96     |> cast(data, __schema__(:fields) -- [:attachment])
  97     |> cast_embed(:attachment)
  98   end
  99
 100   def validate_data(data_cng) do
 101     data_cng
 102     |> validate_inclusion(:type, ["Audio"])
 103     |> validate_required([:id, :actor, :attributedTo, :type, :context])
 104     |> CommonValidations.validate_any_presence([:cc, :to])
 105     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 106     |> CommonValidations.validate_actor_presence()
 107     |> CommonValidations.validate_host_match()
 108   end
 109 end