git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/audio_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AudioValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  12
  13   import Ecto.Changeset
  14
  15   @primary_key false
  16   @derive Jason.Encoder
  17
  18   embedded_schema do
  19     field(:id, ObjectValidators.ObjectID, primary_key: true)
  20     field(:to, ObjectValidators.Recipients, default: [])
  21     field(:cc, ObjectValidators.Recipients, default: [])
  22     field(:bto, ObjectValidators.Recipients, default: [])
  23     field(:bcc, ObjectValidators.Recipients, default: [])
  24     # TODO: Write type
  25     field(:tag, {:array, :map}, default: [])
  26     field(:type, :string)
  27     field(:content, :string)
  28     field(:context, :string)
  29
  30     # TODO: Remove actor on objects
  31     field(:actor, ObjectValidators.ObjectID)
  32
  33     field(:attributedTo, ObjectValidators.ObjectID)
  34     field(:summary, :string)
  35     field(:published, ObjectValidators.DateTime)
  36     # TODO: Write type
  37     field(:emoji, :map, default: %{})
  38     field(:sensitive, :boolean, default: false)
  39     embeds_many(:attachment, AttachmentValidator)
  40     field(:replies_count, :integer, default: 0)
  41     field(:like_count, :integer, default: 0)
  42     field(:announcement_count, :integer, default: 0)
  43     field(:inReplyTo, :string)
  44     field(:uri, ObjectValidators.Uri)
  45     # short identifier for PleromaFE to group statuses by context
  46     field(:context_id, :integer)
  47
  48     field(:likes, {:array, :string}, default: [])
  49     field(:announcements, {:array, :string}, default: [])
  50   end
  51
  52   def cast_and_apply(data) do
  53     data
  54     |> cast_data
  55     |> apply_action(:insert)
  56   end
  57
  58   def cast_and_validate(data) do
  59     data
  60     |> cast_data()
  61     |> validate_data()
  62   end
  63
  64   def cast_data(data) do
  65     %__MODULE__{}
  66     |> changeset(data)
  67   end
  68
  69   defp fix(data) do
  70     data
  71     |> CommonFixes.fix_defaults()
  72     |> CommonFixes.fix_attribution()
  73   end
  74
  75   def changeset(struct, data) do
  76     data = fix(data)
  77
  78     struct
  79     |> cast(data, __schema__(:fields) -- [:attachment])
  80     |> cast_embed(:attachment)
  81   end
  82
  83   def validate_data(data_cng) do
  84     data_cng
  85     |> validate_inclusion(:type, ["Audio"])
  86     |> validate_required([:id, :actor, :attributedTo, :type, :context])
  87     |> CommonValidations.validate_any_presence([:cc, :to])
  88     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
  89     |> CommonValidations.validate_actor_presence()
  90     |> CommonValidations.validate_host_match()
  91   end
  92 end