git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/attachment_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9
  10   import Ecto.Changeset
  11
  12   @primary_key false
  13   embedded_schema do
  14     field(:type, :string)
  15     field(:mediaType, :string, default: "application/octet-stream")
  16     field(:name, :string)
  17     field(:blurhash, :string)
  18
  19     embeds_many :url, UrlObjectValidator, primary_key: false do
  20       field(:type, :string)
  21       field(:href, ObjectValidators.Uri)
  22       field(:mediaType, :string, default: "application/octet-stream")
  23     end
  24   end
  25
  26   def cast_and_validate(data) do
  27     data
  28     |> cast_data()
  29     |> validate_data()
  30   end
  31
  32   def cast_data(data) do
  33     %__MODULE__{}
  34     |> changeset(data)
  35   end
  36
  37   def changeset(struct, data) do
  38     data =
  39       data
  40       |> fix_media_type()
  41       |> fix_url()
  42
  43     struct
  44     |> cast(data, [:type, :mediaType, :name, :blurhash])
  45     |> cast_embed(:url, with: &url_changeset/2)
  46     |> validate_inclusion(:type, ~w[Link Document Audio Image Video])
  47     |> validate_required([:type, :mediaType, :url])
  48   end
  49
  50   def url_changeset(struct, data) do
  51     data = fix_media_type(data)
  52
  53     struct
  54     |> cast(data, [:type, :href, :mediaType])
  55     |> validate_inclusion(:type, ["Link"])
  56     |> validate_required([:type, :href, :mediaType])
  57   end
  58
  59   def fix_media_type(data) do
  60     data = Map.put_new(data, "mediaType", data["mimeType"])
  61
  62     if MIME.valid?(data["mediaType"]) do
  63       data
  64     else
  65       Map.put(data, "mediaType", "application/octet-stream")
  66     end
  67   end
  68
  69   defp handle_href(href, mediaType) do
  70     [
  71       %{
  72         "href" => href,
  73         "type" => "Link",
  74         "mediaType" => mediaType
  75       }
  76     ]
  77   end
  78
  79   defp fix_url(data) do
  80     cond do
  81       is_binary(data["url"]) ->
  82         Map.put(data, "url", handle_href(data["url"], data["mediaType"]))
  83
  84       is_binary(data["href"]) and data["url"] == nil ->
  85         Map.put(data, "url", handle_href(data["href"], data["mediaType"]))
  86
  87       true ->
  88         data
  89     end
  90   end
  91
  92   def validate_data(cng) do
  93     cng
  94     |> validate_inclusion(:type, ~w[Document Audio Image Video])
  95     |> validate_required([:mediaType, :url, :type])
  96   end
  97 end