git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/article_note_page_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Object.Fetcher
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13
  14   import Ecto.Changeset
  15
  16   require Logger
  17
  18   @primary_key false
  19   @derive Jason.Encoder
  20
  21   embedded_schema do
  22     quote do
  23       unquote do
  24         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  25         message_fields()
  26         object_fields()
  27         status_object_fields()
  28       end
  29     end
  30
  31     field(:replies, {:array, ObjectValidators.ObjectID}, default: [])
  32   end
  33
  34   def cast_and_apply(data) do
  35     data
  36     |> cast_data
  37     |> apply_action(:insert)
  38   end
  39
  40   def cast_and_validate(data) do
  41     data
  42     |> cast_data()
  43     |> validate_data()
  44   end
  45
  46   def cast_data(data) do
  47     %__MODULE__{}
  48     |> changeset(data)
  49   end
  50
  51   defp fix_url(%{"url" => url} = data) when is_bitstring(url), do: data
  52   defp fix_url(%{"url" => url} = data) when is_map(url), do: Map.put(data, "url", url["href"])
  53   defp fix_url(data), do: data
  54
  55   defp fix_tag(%{"tag" => tag} = data) when is_list(tag), do: data
  56   defp fix_tag(%{"tag" => tag} = data) when is_map(tag), do: Map.put(data, "tag", [tag])
  57   defp fix_tag(data), do: Map.drop(data, ["tag"])
  58
  59   defp fix_replies(%{"replies" => %{"first" => %{"items" => replies}}} = data)
  60        when is_list(replies),
  61        do: Map.put(data, "replies", replies)
  62
  63   defp fix_replies(%{"replies" => %{"items" => replies}} = data) when is_list(replies),
  64     do: Map.put(data, "replies", replies)
  65
  66   defp fix_replies(%{"replies" => replies} = data) when is_bitstring(replies),
  67     do: Map.drop(data, ["replies"])
  68
  69   defp fix_replies(%{"replies" => %{"first" => first}} = data) do
  70     with {:ok, %{"orderedItems" => replies}} <-
  71            Fetcher.fetch_and_contain_remote_object_from_id(first) do
  72       Map.put(data, "replies", replies)
  73     else
  74       {:error, _} ->
  75         Logger.error("Could not fetch replies for #{first}")
  76         Map.put(data, "replies", [])
  77     end
  78   end
  79
  80   defp fix_replies(data), do: data
  81
  82   defp fix(data) do
  83     data
  84     |> CommonFixes.fix_actor()
  85     |> CommonFixes.fix_object_defaults()
  86     |> fix_url()
  87     |> fix_tag()
  88     |> fix_replies()
  89     |> Transmogrifier.fix_emoji()
  90     |> Transmogrifier.fix_content_map()
  91   end
  92
  93   def changeset(struct, data) do
  94     data = fix(data)
  95
  96     struct
  97     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
  98     |> cast_embed(:attachment)
  99     |> cast_embed(:tag)
 100   end
 101
 102   defp validate_data(data_cng) do
 103     data_cng
 104     |> validate_inclusion(:type, ["Article", "Note", "Page"])
 105     |> validate_required([:id, :actor, :attributedTo, :type, :context, :context_id])
 106     |> CommonValidations.validate_any_presence([:cc, :to])
 107     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 108     |> CommonValidations.validate_actor_presence()
 109     |> CommonValidations.validate_host_match()
 110   end
 111 end