git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/article_note_page_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Object.Fetcher
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  12   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13   alias Pleroma.Web.ActivityPub.Transmogrifier
  14
  15   import Ecto.Changeset
  16
  17   require Logger
  18
  19   @primary_key false
  20   @derive Jason.Encoder
  21
  22   embedded_schema do
  23     quote do
  24       unquote do
  25         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  26         message_fields()
  27         object_fields()
  28         status_object_fields()
  29       end
  30     end
  31
  32     field(:replies, {:array, ObjectValidators.ObjectID}, default: [])
  33     field(:source, :map)
  34   end
  35
  36   def cast_and_apply(data) do
  37     data
  38     |> cast_data
  39     |> apply_action(:insert)
  40   end
  41
  42   def cast_and_validate(data) do
  43     data
  44     |> cast_data()
  45     |> validate_data()
  46   end
  47
  48   def cast_data(data) do
  49     %__MODULE__{}
  50     |> changeset(data)
  51   end
  52
  53   defp fix_url(%{"url" => url} = data) when is_bitstring(url), do: data
  54   defp fix_url(%{"url" => url} = data) when is_map(url), do: Map.put(data, "url", url["href"])
  55   defp fix_url(data), do: data
  56
  57   defp fix_tag(%{"tag" => tag} = data) when is_list(tag), do: data
  58   defp fix_tag(%{"tag" => tag} = data) when is_map(tag), do: Map.put(data, "tag", [tag])
  59   defp fix_tag(data), do: Map.drop(data, ["tag"])
  60
  61   defp fix_replies(%{"replies" => %{"first" => %{"items" => replies}}} = data)
  62        when is_list(replies),
  63        do: Map.put(data, "replies", replies)
  64
  65   defp fix_replies(%{"replies" => %{"items" => replies}} = data) when is_list(replies),
  66     do: Map.put(data, "replies", replies)
  67
  68   defp fix_replies(%{"replies" => replies} = data) when is_bitstring(replies),
  69     do: Map.drop(data, ["replies"])
  70
  71   defp fix_replies(%{"replies" => %{"first" => first}} = data) do
  72     with {:ok, %{"orderedItems" => replies}} <-
  73            Fetcher.fetch_and_contain_remote_object_from_id(first) do
  74       Map.put(data, "replies", replies)
  75     else
  76       {:error, _} ->
  77         Logger.error("Could not fetch replies for #{first}")
  78         Map.put(data, "replies", [])
  79     end
  80   end
  81
  82   defp fix_replies(data), do: data
  83
  84   # https://github.com/misskey-dev/misskey/pull/8787
  85   defp fix_misskey_content(
  86          %{"source" => %{"mediaType" => "text/x.misskeymarkdown", "content" => content}} = object
  87        ) do
  88     {linked, _, _} = Utils.format_input(content, "text/x.misskeymarkdown")
  89     Map.put(object, "content", linked)
  90   end
  91
  92   defp fix_misskey_content(%{"_misskey_content" => content} = object) do
  93     {linked, _, _} = Utils.format_input(content, "text/x.misskeymarkdown")
  94
  95     object
  96     |> Map.put("source", %{
  97       "content" => content,
  98       "mediaType" => "text/x.misskeymarkdown"
  99     })
 100     |> Map.put("content", linked)
 101     |> Map.delete("_misskey_content")
 102   end
 103
 104   defp fix_misskey_content(data), do: data
 105
 106   defp fix_source(%{"source" => source} = object) when is_binary(source) do
 107     object
 108     |> Map.put("source", %{"content" => source})
 109   end
 110
 111   defp fix_source(object), do: object
 112
 113   defp fix(data) do
 114     data
 115     |> CommonFixes.fix_actor()
 116     |> CommonFixes.fix_object_defaults()
 117     |> fix_url()
 118     |> fix_tag()
 119     |> fix_replies()
 120     |> fix_source()
 121     |> fix_misskey_content()
 122     |> Transmogrifier.fix_attachments()
 123     |> Transmogrifier.fix_emoji()
 124     |> Transmogrifier.fix_content_map()
 125   end
 126
 127   def changeset(struct, data) do
 128     data = fix(data)
 129
 130     struct
 131     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
 132     |> cast_embed(:attachment)
 133     |> cast_embed(:tag)
 134   end
 135
 136   defp validate_data(data_cng) do
 137     data_cng
 138     |> validate_inclusion(:type, ["Article", "Note", "Page"])
 139     |> validate_required([:id, :actor, :attributedTo, :type, :context, :context_id])
 140     |> CommonValidations.validate_any_presence([:cc, :to])
 141     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 142     |> CommonValidations.validate_actor_presence()
 143     |> CommonValidations.validate_host_match()
 144   end
 145 end