git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/article_note_page_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Object.Fetcher
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13
  14   import Ecto.Changeset
  15
  16   require Logger
  17
  18   @primary_key false
  19   @derive Jason.Encoder
  20
  21   embedded_schema do
  22     quote do
  23       unquote do
  24         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  25         message_fields()
  26         object_fields()
  27         status_object_fields()
  28       end
  29     end
  30
  31     field(:replies, {:array, ObjectValidators.ObjectID}, default: [])
  32     field(:source, :map)
  33   end
  34
  35   def cast_and_apply(data) do
  36     data
  37     |> cast_data
  38     |> apply_action(:insert)
  39   end
  40
  41   def cast_and_validate(data) do
  42     data
  43     |> cast_data()
  44     |> validate_data()
  45   end
  46
  47   def cast_data(data) do
  48     %__MODULE__{}
  49     |> changeset(data)
  50   end
  51
  52   defp fix_url(%{"url" => url} = data) when is_bitstring(url), do: data
  53   defp fix_url(%{"url" => url} = data) when is_map(url), do: Map.put(data, "url", url["href"])
  54   defp fix_url(data), do: data
  55
  56   defp fix_tag(%{"tag" => tag} = data) when is_list(tag), do: data
  57   defp fix_tag(%{"tag" => tag} = data) when is_map(tag), do: Map.put(data, "tag", [tag])
  58   defp fix_tag(data), do: Map.drop(data, ["tag"])
  59
  60   defp fix_replies(%{"replies" => %{"first" => %{"items" => replies}}} = data)
  61        when is_list(replies),
  62        do: Map.put(data, "replies", replies)
  63
  64   defp fix_replies(%{"replies" => %{"items" => replies}} = data) when is_list(replies),
  65     do: Map.put(data, "replies", replies)
  66
  67   defp fix_replies(%{"replies" => replies} = data) when is_bitstring(replies),
  68     do: Map.drop(data, ["replies"])
  69
  70   defp fix_replies(%{"replies" => %{"first" => first}} = data) do
  71     with {:ok, %{"orderedItems" => replies}} <-
  72            Fetcher.fetch_and_contain_remote_object_from_id(first) do
  73       Map.put(data, "replies", replies)
  74     else
  75       {:error, _} ->
  76         Logger.error("Could not fetch replies for #{first}")
  77         Map.put(data, "replies", [])
  78     end
  79   end
  80
  81   defp fix_replies(data), do: data
  82
  83   # https://github.com/misskey-dev/misskey/pull/8787
  84   defp fix_misskey_content(%{"source" => %{"mediaType" => "text/x.misskeymarkdown"}} = object),
  85     do: object
  86
  87   defp fix_misskey_content(%{"_misskey_content" => content} = object) do
  88     object
  89     |> Map.put("source", %{"content" => content, "mediaType" => "text/x.misskeymarkdown"})
  90     |> Map.delete("_misskey_content")
  91   end
  92
  93   defp fix_misskey_content(data), do: data
  94
  95   defp fix_source(%{"source" => source} = object) when is_binary(source) do
  96     object
  97     |> Map.put("source", %{"content" => source})
  98   end
  99
 100   defp fix_source(object), do: object
 101
 102   defp fix(data) do
 103     data
 104     |> CommonFixes.fix_actor()
 105     |> CommonFixes.fix_object_defaults()
 106     |> fix_url()
 107     |> fix_tag()
 108     |> fix_replies()
 109     |> fix_source()
 110     |> fix_misskey_content()
 111     |> Transmogrifier.fix_attachments()
 112     |> Transmogrifier.fix_emoji()
 113     |> Transmogrifier.fix_content_map()
 114   end
 115
 116   def changeset(struct, data) do
 117     data = fix(data)
 118
 119     struct
 120     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
 121     |> cast_embed(:attachment)
 122     |> cast_embed(:tag)
 123   end
 124
 125   defp validate_data(data_cng) do
 126     data_cng
 127     |> validate_inclusion(:type, ["Article", "Note", "Page"])
 128     |> validate_required([:id, :actor, :attributedTo, :type, :context, :context_id])
 129     |> CommonValidations.validate_any_presence([:cc, :to])
 130     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 131     |> CommonValidations.validate_actor_presence()
 132     |> CommonValidations.validate_host_match()
 133   end
 134 end