git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/article_note_page_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  11   alias Pleroma.Web.ActivityPub.Transmogrifier
  12
  13   import Ecto.Changeset
  14
  15   @primary_key false
  16   @derive Jason.Encoder
  17
  18   embedded_schema do
  19     quote do
  20       unquote do
  21         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  22         message_fields()
  23         object_fields()
  24         status_object_fields()
  25       end
  26     end
  27
  28     field(:replies, {:array, ObjectValidators.ObjectID}, default: [])
  29   end
  30
  31   def cast_and_apply(data) do
  32     data
  33     |> cast_data
  34     |> apply_action(:insert)
  35   end
  36
  37   def cast_and_validate(data) do
  38     data
  39     |> cast_data()
  40     |> validate_data()
  41   end
  42
  43   def cast_data(data) do
  44     %__MODULE__{}
  45     |> changeset(data)
  46   end
  47
  48   defp fix_url(%{"url" => url} = data) when is_bitstring(url), do: data
  49   defp fix_url(%{"url" => url} = data) when is_map(url), do: Map.put(data, "url", url["href"])
  50   defp fix_url(data), do: data
  51
  52   defp fix_tag(%{"tag" => tag} = data) when is_list(tag), do: data
  53   defp fix_tag(%{"tag" => tag} = data) when is_map(tag), do: Map.put(data, "tag", [tag])
  54   defp fix_tag(data), do: Map.drop(data, ["tag"])
  55
  56   defp fix_replies(%{"replies" => %{"first" => %{"items" => replies}}} = data)
  57        when is_list(replies),
  58        do: Map.put(data, "replies", replies)
  59
  60   defp fix_replies(%{"replies" => %{"items" => replies}} = data) when is_list(replies),
  61     do: Map.put(data, "replies", replies)
  62
  63   defp fix_replies(%{"replies" => replies} = data) when is_bitstring(replies),
  64     do: Map.drop(data, ["replies"])
  65
  66   defp fix_replies(data), do: data
  67
  68   defp fix(data) do
  69     data
  70     |> CommonFixes.fix_actor()
  71     |> CommonFixes.fix_object_defaults()
  72     |> fix_url()
  73     |> fix_tag()
  74     |> fix_replies()
  75     |> Transmogrifier.fix_emoji()
  76     |> Transmogrifier.fix_content_map()
  77   end
  78
  79   def changeset(struct, data) do
  80     data = fix(data)
  81
  82     struct
  83     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
  84     |> cast_embed(:attachment)
  85     |> cast_embed(:tag)
  86   end
  87
  88   defp validate_data(data_cng) do
  89     data_cng
  90     |> validate_inclusion(:type, ["Article", "Note", "Page"])
  91     |> validate_required([:id, :actor, :attributedTo, :type, :context, :context_id])
  92     |> CommonValidations.validate_any_presence([:cc, :to])
  93     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
  94     |> CommonValidations.validate_actor_presence()
  95     |> CommonValidations.validate_host_match()
  96   end
  97 end