git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/add_remove_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AddRemoveValidator do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  10
  11   require Pleroma.Constants
  12
  13   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, ObjectValidators.ObjectID, primary_key: true)
  19     field(:target)
  20     field(:object, ObjectValidators.ObjectID)
  21     field(:actor, ObjectValidators.ObjectID)
  22     field(:type)
  23     field(:to, ObjectValidators.Recipients, default: [])
  24     field(:cc, ObjectValidators.Recipients, default: [])
  25   end
  26
  27   def cast_and_validate(data) do
  28     data
  29     |> maybe_fix_data_for_mastodon()
  30     |> cast_data()
  31     |> validate_data()
  32   end
  33
  34   defp maybe_fix_data_for_mastodon(data) do
  35     {:ok, actor} = Pleroma.User.get_or_fetch_by_ap_id(data["actor"])
  36     # Mastodon sends pin/unpin objects without id, to, cc fields
  37     data
  38     |> Map.put_new("id", Pleroma.Web.ActivityPub.Utils.generate_activity_id())
  39     |> Map.put_new("to", [Pleroma.Constants.as_public()])
  40     |> Map.put_new("cc", [actor.follower_address])
  41   end
  42
  43   defp cast_data(data) do
  44     cast(%__MODULE__{}, data, __schema__(:fields))
  45   end
  46
  47   defp validate_data(changeset) do
  48     changeset
  49     |> validate_required([:id, :target, :object, :actor, :type, :to, :cc])
  50     |> validate_inclusion(:type, ~w(Add Remove))
  51     |> validate_actor_presence()
  52     |> validate_collection_belongs_to_actor()
  53     |> validate_object_presence()
  54   end
  55
  56   defp validate_collection_belongs_to_actor(changeset) do
  57     {:ok, actor} = Pleroma.User.get_or_fetch_by_ap_id(changeset.changes[:actor])
  58
  59     validate_change(changeset, :target, fn :target, target ->
  60       if target == actor.featured_address do
  61         []
  62       else
  63         [target: "collection doesn't belong to actor"]
  64       end
  65     end)
  66   end
  67 end