git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/add_remove_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AddRemoveValidator do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  10
  11   require Pleroma.Constants
  12
  13   alias Pleroma.User
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:target)
  19
  20     quote do
  21       unquote do
  22         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  23         message_fields()
  24         activity_fields()
  25       end
  26     end
  27   end
  28
  29   def cast_and_validate(data) do
  30     {:ok, actor} = User.get_or_fetch_by_ap_id(data["actor"])
  31
  32     {:ok, actor} = maybe_refetch_user(actor)
  33
  34     data
  35     |> maybe_fix_data_for_mastodon(actor)
  36     |> cast_data()
  37     |> validate_data(actor)
  38   end
  39
  40   defp maybe_fix_data_for_mastodon(data, actor) do
  41     # Mastodon sends pin/unpin objects without id, to, cc fields
  42     data
  43     |> Map.put_new("id", Pleroma.Web.ActivityPub.Utils.generate_activity_id())
  44     |> Map.put_new("to", [Pleroma.Constants.as_public()])
  45     |> Map.put_new("cc", [actor.follower_address])
  46   end
  47
  48   defp cast_data(data) do
  49     cast(%__MODULE__{}, data, __schema__(:fields))
  50   end
  51
  52   defp validate_data(changeset, actor) do
  53     changeset
  54     |> validate_required([:id, :target, :object, :actor, :type, :to, :cc])
  55     |> validate_inclusion(:type, ~w(Add Remove))
  56     |> validate_actor_presence()
  57     |> validate_collection_belongs_to_actor(actor)
  58     |> validate_object_presence()
  59   end
  60
  61   defp validate_collection_belongs_to_actor(changeset, actor) do
  62     validate_change(changeset, :target, fn :target, target ->
  63       if target == actor.featured_address do
  64         []
  65       else
  66         [target: "collection doesn't belong to actor"]
  67       end
  68     end)
  69   end
  70
  71   defp maybe_refetch_user(%User{featured_address: address} = user) when is_binary(address) do
  72     {:ok, user}
  73   end
  74
  75   defp maybe_refetch_user(%User{ap_id: ap_id}) do
  76     Pleroma.Web.ActivityPub.Transmogrifier.upgrade_user_from_ap_id(ap_id)
  77   end
  78 end