git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/add_remove_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AddRemoveValidator do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  10
  11   require Pleroma.Constants
  12
  13   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  14   alias Pleroma.User
  15
  16   @primary_key false
  17
  18   embedded_schema do
  19     field(:id, ObjectValidators.ObjectID, primary_key: true)
  20     field(:target)
  21     field(:object, ObjectValidators.ObjectID)
  22     field(:actor, ObjectValidators.ObjectID)
  23     field(:type)
  24     field(:to, ObjectValidators.Recipients, default: [])
  25     field(:cc, ObjectValidators.Recipients, default: [])
  26   end
  27
  28   def cast_and_validate(data) do
  29     {:ok, actor} = User.get_or_fetch_by_ap_id(data["actor"])
  30
  31     {:ok, actor} = maybe_refetch_user(actor)
  32
  33     data
  34     |> maybe_fix_data_for_mastodon(actor)
  35     |> cast_data()
  36     |> validate_data(actor)
  37   end
  38
  39   defp maybe_fix_data_for_mastodon(data, actor) do
  40     # Mastodon sends pin/unpin objects without id, to, cc fields
  41     data
  42     |> Map.put_new("id", Pleroma.Web.ActivityPub.Utils.generate_activity_id())
  43     |> Map.put_new("to", [Pleroma.Constants.as_public()])
  44     |> Map.put_new("cc", [actor.follower_address])
  45   end
  46
  47   defp cast_data(data) do
  48     cast(%__MODULE__{}, data, __schema__(:fields))
  49   end
  50
  51   defp validate_data(changeset, actor) do
  52     changeset
  53     |> validate_required([:id, :target, :object, :actor, :type, :to, :cc])
  54     |> validate_inclusion(:type, ~w(Add Remove))
  55     |> validate_actor_presence()
  56     |> validate_collection_belongs_to_actor(actor)
  57     |> validate_object_presence()
  58   end
  59
  60   defp validate_collection_belongs_to_actor(changeset, actor) do
  61     validate_change(changeset, :target, fn :target, target ->
  62       if target == actor.featured_address do
  63         []
  64       else
  65         [target: "collection doesn't belong to actor"]
  66       end
  67     end)
  68   end
  69
  70   defp maybe_refetch_user(%User{featured_address: address} = user) when is_binary(address) do
  71     {:ok, user}
  72   end
  73
  74   defp maybe_refetch_user(%User{ap_id: ap_id}) do
  75     Pleroma.Web.ActivityPub.Transmogrifier.upgrade_user_from_ap_id(ap_id)
  76   end
  77 end