git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/accept_reject_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  10
  11   import Ecto.Changeset
  12   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13
  14   @primary_key false
  15
  16   embedded_schema do
  17     field(:id, ObjectValidators.ObjectID, primary_key: true)
  18     field(:type, :string)
  19     field(:object, ObjectValidators.ObjectID)
  20     field(:actor, ObjectValidators.ObjectID)
  21     field(:to, ObjectValidators.Recipients, default: [])
  22     field(:cc, ObjectValidators.Recipients, default: [])
  23   end
  24
  25   def cast_data(data) do
  26     %__MODULE__{}
  27     |> cast(data, __schema__(:fields))
  28   end
  29
  30   defp validate_data(cng) do
  31     cng
  32     |> validate_required([:id, :type, :actor, :to, :cc, :object])
  33     |> validate_inclusion(:type, ["Accept", "Reject"])
  34     |> validate_actor_presence()
  35     |> validate_object_presence(allowed_types: ["Follow"])
  36     |> validate_accept_reject_rights()
  37   end
  38
  39   def cast_and_validate(data) do
  40     data
  41     |> cast_data
  42     |> validate_data
  43   end
  44
  45   def validate_accept_reject_rights(cng) do
  46     with object_id when is_binary(object_id) <- get_field(cng, :object),
  47          %Activity{data: %{"object" => followed_actor}} <- Activity.get_by_ap_id(object_id),
  48          true <- followed_actor == get_field(cng, :actor) do
  49       cng
  50     else
  51       _e ->
  52         cng
  53         |> add_error(:actor, "can't accept or reject the given activity")
  54     end
  55   end
  56 end