git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  20
  21   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  22   def validate(object, meta)
  23
  24   def validate(%{"type" => "Undo"} = object, meta) do
  25     with {:ok, object} <-
  26            object
  27            |> UndoValidator.cast_and_validate()
  28            |> Ecto.Changeset.apply_action(:insert) do
  29       object = stringify_keys(object)
  30       {:ok, object, meta}
  31     end
  32   end
  33
  34   def validate(%{"type" => "Delete"} = object, meta) do
  35     with cng <- DeleteValidator.cast_and_validate(object),
  36          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  37          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  38       object = stringify_keys(object)
  39       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  40       {:ok, object, meta}
  41     end
  42   end
  43
  44   def validate(%{"type" => "Like"} = object, meta) do
  45     with {:ok, object} <-
  46            object |> LikeValidator.cast_and_validate() |> Ecto.Changeset.apply_action(:insert) do
  47       object = stringify_keys(object |> Map.from_struct())
  48       {:ok, object, meta}
  49     end
  50   end
  51
  52   def validate(%{"type" => "EmojiReact"} = object, meta) do
  53     with {:ok, object} <-
  54            object
  55            |> EmojiReactValidator.cast_and_validate()
  56            |> Ecto.Changeset.apply_action(:insert) do
  57       object = stringify_keys(object |> Map.from_struct())
  58       {:ok, object, meta}
  59     end
  60   end
  61
  62   def validate(%{"type" => "Announce"} = object, meta) do
  63     with {:ok, object} <-
  64            object
  65            |> AnnounceValidator.cast_and_validate()
  66            |> Ecto.Changeset.apply_action(:insert) do
  67       object = stringify_keys(object |> Map.from_struct())
  68       {:ok, object, meta}
  69     end
  70   end
  71
  72   def stringify_keys(%{__struct__: _} = object) do
  73     object
  74     |> Map.from_struct()
  75     |> stringify_keys
  76   end
  77
  78   def stringify_keys(object) do
  79     object
  80     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  81   end
  82
  83   def fetch_actor(object) do
  84     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
  85       User.get_or_fetch_by_ap_id(actor)
  86     end
  87   end
  88
  89   def fetch_actor_and_object(object) do
  90     fetch_actor(object)
  91     Object.normalize(object["object"])
  92     :ok
  93   end
  94 end