git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNoteValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  35   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  36
  37   @impl true
  38   def validate(object, meta)
  39
  40   def validate(%{"type" => "Block"} = block_activity, meta) do
  41     with {:ok, block_activity} <-
  42            block_activity
  43            |> BlockValidator.cast_and_validate()
  44            |> Ecto.Changeset.apply_action(:insert) do
  45       block_activity = stringify_keys(block_activity)
  46       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  47
  48       meta =
  49         if !outgoing_blocks do
  50           Keyword.put(meta, :do_not_federate, true)
  51         else
  52           meta
  53         end
  54
  55       {:ok, block_activity, meta}
  56     end
  57   end
  58
  59   def validate(%{"type" => "Undo"} = object, meta) do
  60     with {:ok, object} <-
  61            object
  62            |> UndoValidator.cast_and_validate()
  63            |> Ecto.Changeset.apply_action(:insert) do
  64       object = stringify_keys(object)
  65       undone_object = Activity.get_by_ap_id(object["object"])
  66
  67       meta =
  68         meta
  69         |> Keyword.put(:object_data, undone_object.data)
  70
  71       {:ok, object, meta}
  72     end
  73   end
  74
  75   def validate(%{"type" => "Delete"} = object, meta) do
  76     with cng <- DeleteValidator.cast_and_validate(object),
  77          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  78          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  79       object = stringify_keys(object)
  80       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  81       {:ok, object, meta}
  82     end
  83   end
  84
  85   def validate(
  86         %{"type" => "Create", "object" => %{"type" => "ChatMessage"} = object} = create_activity,
  87         meta
  88       ) do
  89     with {:ok, object_data} <- cast_and_apply(object),
  90          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  91          {:ok, create_activity} <-
  92            create_activity
  93            |> CreateChatMessageValidator.cast_and_validate(meta)
  94            |> Ecto.Changeset.apply_action(:insert) do
  95       create_activity = stringify_keys(create_activity)
  96       {:ok, create_activity, meta}
  97     end
  98   end
  99
 100   def validate(
 101         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
 102         meta
 103       )
 104       when objtype in ~w[Question Answer Audio Video Event Article Note] do
 105     with {:ok, object_data} <- cast_and_apply(object),
 106          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 107          {:ok, create_activity} <-
 108            create_activity
 109            |> CreateGenericValidator.cast_and_validate(meta)
 110            |> Ecto.Changeset.apply_action(:insert) do
 111       create_activity = stringify_keys(create_activity)
 112       {:ok, create_activity, meta}
 113     end
 114   end
 115
 116   def validate(%{"type" => type} = object, meta)
 117       when type in ~w[Event Question Audio Video Article Note] do
 118     validator =
 119       case type do
 120         "Event" -> EventValidator
 121         "Question" -> QuestionValidator
 122         "Audio" -> AudioVideoValidator
 123         "Video" -> AudioVideoValidator
 124         "Article" -> ArticleNoteValidator
 125         "Note" -> ArticleNoteValidator
 126       end
 127
 128     with {:ok, object} <-
 129            object
 130            |> validator.cast_and_validate()
 131            |> Ecto.Changeset.apply_action(:insert) do
 132       object = stringify_keys(object)
 133
 134       # Insert copy of hashtags as strings for the non-hashtag table indexing
 135       tag = (object["tag"] || []) ++ Object.hashtags(%Object{data: object})
 136       object = Map.put(object, "tag", tag)
 137
 138       {:ok, object, meta}
 139     end
 140   end
 141
 142   def validate(%{"type" => type} = object, meta)
 143       when type in ~w[Accept Reject Follow Update Like EmojiReact Announce
 144       ChatMessage Answer] do
 145     validator =
 146       case type do
 147         "Accept" -> AcceptRejectValidator
 148         "Reject" -> AcceptRejectValidator
 149         "Follow" -> FollowValidator
 150         "Update" -> UpdateValidator
 151         "Like" -> LikeValidator
 152         "EmojiReact" -> EmojiReactValidator
 153         "Announce" -> AnnounceValidator
 154         "ChatMessage" -> ChatMessageValidator
 155         "Answer" -> AnswerValidator
 156       end
 157
 158     with {:ok, object} <-
 159            object
 160            |> validator.cast_and_validate()
 161            |> Ecto.Changeset.apply_action(:insert) do
 162       object = stringify_keys(object)
 163       {:ok, object, meta}
 164     end
 165   end
 166
 167   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 168     ChatMessageValidator.cast_and_apply(object)
 169   end
 170
 171   def cast_and_apply(%{"type" => "Question"} = object) do
 172     QuestionValidator.cast_and_apply(object)
 173   end
 174
 175   def cast_and_apply(%{"type" => "Answer"} = object) do
 176     AnswerValidator.cast_and_apply(object)
 177   end
 178
 179   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 180     AudioVideoValidator.cast_and_apply(object)
 181   end
 182
 183   def cast_and_apply(%{"type" => "Event"} = object) do
 184     EventValidator.cast_and_apply(object)
 185   end
 186
 187   def cast_and_apply(%{"type" => type} = object) when type in ~w[Article Note] do
 188     ArticleNoteValidator.cast_and_apply(object)
 189   end
 190
 191   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 192
 193   # is_struct/1 appears in Elixir 1.11
 194   def stringify_keys(%{__struct__: _} = object) do
 195     object
 196     |> Map.from_struct()
 197     |> stringify_keys
 198   end
 199
 200   def stringify_keys(object) when is_map(object) do
 201     object
 202     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 203   end
 204
 205   def stringify_keys(object) when is_list(object) do
 206     object
 207     |> Enum.map(&stringify_keys/1)
 208   end
 209
 210   def stringify_keys(object), do: object
 211
 212   def fetch_actor(object) do
 213     with actor <- Containment.get_actor(object),
 214          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 215       User.get_or_fetch_by_ap_id(actor)
 216     end
 217   end
 218
 219   def fetch_actor_and_object(object) do
 220     fetch_actor(object)
 221     Object.normalize(object["object"], fetch: true)
 222     :ok
 223   end
 224 end