git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Activity
  13   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  14   alias Pleroma.Object
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  29
  30   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  31   def validate(object, meta)
  32
  33   def validate(%{"type" => "Follow"} = object, meta) do
  34     with {:ok, object} <-
  35            object
  36            |> FollowValidator.cast_and_validate()
  37            |> Ecto.Changeset.apply_action(:insert) do
  38       object = stringify_keys(object)
  39       {:ok, object, meta}
  40     end
  41   end
  42
  43   def validate(%{"type" => "Block"} = block_activity, meta) do
  44     with {:ok, block_activity} <-
  45            block_activity
  46            |> BlockValidator.cast_and_validate()
  47            |> Ecto.Changeset.apply_action(:insert) do
  48       block_activity = stringify_keys(block_activity)
  49       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  50
  51       meta =
  52         if !outgoing_blocks do
  53           Keyword.put(meta, :do_not_federate, true)
  54         else
  55           meta
  56         end
  57
  58       {:ok, block_activity, meta}
  59     end
  60   end
  61
  62   def validate(%{"type" => "Update"} = update_activity, meta) do
  63     with {:ok, update_activity} <-
  64            update_activity
  65            |> UpdateValidator.cast_and_validate()
  66            |> Ecto.Changeset.apply_action(:insert) do
  67       update_activity = stringify_keys(update_activity)
  68       {:ok, update_activity, meta}
  69     end
  70   end
  71
  72   def validate(%{"type" => "Undo"} = object, meta) do
  73     with {:ok, object} <-
  74            object
  75            |> UndoValidator.cast_and_validate()
  76            |> Ecto.Changeset.apply_action(:insert) do
  77       object = stringify_keys(object)
  78       undone_object = Activity.get_by_ap_id(object["object"])
  79
  80       meta =
  81         meta
  82         |> Keyword.put(:object_data, undone_object.data)
  83
  84       {:ok, object, meta}
  85     end
  86   end
  87
  88   def validate(%{"type" => "Delete"} = object, meta) do
  89     with cng <- DeleteValidator.cast_and_validate(object),
  90          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  91          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  92       object = stringify_keys(object)
  93       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  94       {:ok, object, meta}
  95     end
  96   end
  97
  98   def validate(%{"type" => "Like"} = object, meta) do
  99     with {:ok, object} <-
 100            object
 101            |> LikeValidator.cast_and_validate()
 102            |> Ecto.Changeset.apply_action(:insert) do
 103       object = stringify_keys(object)
 104       {:ok, object, meta}
 105     end
 106   end
 107
 108   def validate(%{"type" => "ChatMessage"} = object, meta) do
 109     with {:ok, object} <-
 110            object
 111            |> ChatMessageValidator.cast_and_validate()
 112            |> Ecto.Changeset.apply_action(:insert) do
 113       object = stringify_keys(object)
 114       {:ok, object, meta}
 115     end
 116   end
 117
 118   def validate(%{"type" => "Question"} = object, meta) do
 119     with {:ok, object} <-
 120            object
 121            |> QuestionValidator.cast_and_validate()
 122            |> Ecto.Changeset.apply_action(:insert) do
 123       object = stringify_keys(object)
 124       {:ok, object, meta}
 125     end
 126   end
 127
 128   def validate(%{"type" => "Answer"} = object, meta) do
 129     with {:ok, object} <-
 130            object
 131            |> AnswerValidator.cast_and_validate()
 132            |> Ecto.Changeset.apply_action(:insert) do
 133       object = stringify_keys(object)
 134       {:ok, object, meta}
 135     end
 136   end
 137
 138   def validate(%{"type" => "EmojiReact"} = object, meta) do
 139     with {:ok, object} <-
 140            object
 141            |> EmojiReactValidator.cast_and_validate()
 142            |> Ecto.Changeset.apply_action(:insert) do
 143       object = stringify_keys(object)
 144       {:ok, object, meta}
 145     end
 146   end
 147
 148   def validate(
 149         %{"type" => "Create", "object" => %{"type" => "ChatMessage"} = object} = create_activity,
 150         meta
 151       ) do
 152     with {:ok, object_data} <- cast_and_apply(object),
 153          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 154          {:ok, create_activity} <-
 155            create_activity
 156            |> CreateChatMessageValidator.cast_and_validate(meta)
 157            |> Ecto.Changeset.apply_action(:insert) do
 158       create_activity = stringify_keys(create_activity)
 159       {:ok, create_activity, meta}
 160     end
 161   end
 162
 163   def validate(
 164         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
 165         meta
 166       )
 167       when objtype in ["Question", "Answer"] do
 168     with {:ok, object_data} <- cast_and_apply(object),
 169          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 170          {:ok, create_activity} <-
 171            create_activity
 172            |> CreateGenericValidator.cast_and_validate(meta)
 173            |> Ecto.Changeset.apply_action(:insert) do
 174       create_activity = stringify_keys(create_activity)
 175       {:ok, create_activity, meta}
 176     end
 177   end
 178
 179   def validate(%{"type" => "Announce"} = object, meta) do
 180     with {:ok, object} <-
 181            object
 182            |> AnnounceValidator.cast_and_validate()
 183            |> Ecto.Changeset.apply_action(:insert) do
 184       object = stringify_keys(object)
 185       {:ok, object, meta}
 186     end
 187   end
 188
 189   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 190     ChatMessageValidator.cast_and_apply(object)
 191   end
 192
 193   def cast_and_apply(%{"type" => "Question"} = object) do
 194     QuestionValidator.cast_and_apply(object)
 195   end
 196
 197   def cast_and_apply(%{"type" => "Answer"} = object) do
 198     AnswerValidator.cast_and_apply(object)
 199   end
 200
 201   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 202
 203   # is_struct/1 isn't present in Elixir 1.8.x
 204   def stringify_keys(%{__struct__: _} = object) do
 205     object
 206     |> Map.from_struct()
 207     |> stringify_keys
 208   end
 209
 210   def stringify_keys(object) when is_map(object) do
 211     object
 212     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 213   end
 214
 215   def stringify_keys(object) when is_list(object) do
 216     object
 217     |> Enum.map(&stringify_keys/1)
 218   end
 219
 220   def stringify_keys(object), do: object
 221
 222   def fetch_actor(object) do
 223     with {:ok, actor} <- ObjectValidators.ObjectID.cast(object["actor"]) do
 224       User.get_or_fetch_by_ap_id(actor)
 225     end
 226   end
 227
 228   def fetch_actor_and_object(object) do
 229     fetch_actor(object)
 230     Object.normalize(object["object"], true)
 231     :ok
 232   end
 233 end