git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AddRemoveValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  35
  36   @impl true
  37   def validate(object, meta)
  38
  39   def validate(%{"type" => "Block"} = block_activity, meta) do
  40     with {:ok, block_activity} <-
  41            block_activity
  42            |> BlockValidator.cast_and_validate()
  43            |> Ecto.Changeset.apply_action(:insert) do
  44       block_activity = stringify_keys(block_activity)
  45       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  46
  47       meta =
  48         if !outgoing_blocks do
  49           Keyword.put(meta, :do_not_federate, true)
  50         else
  51           meta
  52         end
  53
  54       {:ok, block_activity, meta}
  55     end
  56   end
  57
  58   def validate(%{"type" => "Undo"} = object, meta) do
  59     with {:ok, object} <-
  60            object
  61            |> UndoValidator.cast_and_validate()
  62            |> Ecto.Changeset.apply_action(:insert) do
  63       object = stringify_keys(object)
  64       undone_object = Activity.get_by_ap_id(object["object"])
  65
  66       meta =
  67         meta
  68         |> Keyword.put(:object_data, undone_object.data)
  69
  70       {:ok, object, meta}
  71     end
  72   end
  73
  74   def validate(%{"type" => "Delete"} = object, meta) do
  75     with cng <- DeleteValidator.cast_and_validate(object),
  76          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  77          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  78       object = stringify_keys(object)
  79       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  80       {:ok, object, meta}
  81     end
  82   end
  83
  84   def validate(
  85         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
  86         meta
  87       )
  88       when objtype in ~w[Question Answer Audio Video Event Article Note Page] do
  89     with {:ok, object_data} <- cast_and_apply_and_stringify_with_history(object),
  90          meta = Keyword.put(meta, :object_data, object_data),
  91          {:ok, create_activity} <-
  92            create_activity
  93            |> CreateGenericValidator.cast_and_validate(meta)
  94            |> Ecto.Changeset.apply_action(:insert) do
  95       create_activity = stringify_keys(create_activity)
  96       {:ok, create_activity, meta}
  97     end
  98   end
  99
 100   def validate(%{"type" => type} = object, meta)
 101       when type in ~w[Event Question Audio Video Article Note Page] do
 102     validator =
 103       case type do
 104         "Event" -> EventValidator
 105         "Question" -> QuestionValidator
 106         "Audio" -> AudioVideoValidator
 107         "Video" -> AudioVideoValidator
 108         "Article" -> ArticleNotePageValidator
 109         "Note" -> ArticleNotePageValidator
 110         "Page" -> ArticleNotePageValidator
 111       end
 112
 113     with {:ok, object} <-
 114            do_separate_with_history(object, fn object ->
 115              with {:ok, object} <-
 116                     object
 117                     |> validator.cast_and_validate()
 118                     |> Ecto.Changeset.apply_action(:insert) do
 119                object = stringify_keys(object)
 120
 121                # Insert copy of hashtags as strings for the non-hashtag table indexing
 122                tag = (object["tag"] || []) ++ Object.hashtags(%Object{data: object})
 123                object = Map.put(object, "tag", tag)
 124
 125                {:ok, object}
 126              end
 127            end) do
 128       {:ok, object, meta}
 129     end
 130   end
 131
 132   def validate(
 133         %{"type" => "Update", "object" => %{"type" => objtype} = object} = update_activity,
 134         meta
 135       )
 136       when objtype in ~w[Question Answer Audio Video Event Article Note Page] do
 137     with {_, false} <- {:local, Access.get(meta, :local, false)},
 138          {_, {:ok, object_data, _}} <- {:object_validation, validate(object, meta)},
 139          meta = Keyword.put(meta, :object_data, object_data),
 140          {:ok, update_activity} <-
 141            update_activity
 142            |> UpdateValidator.cast_and_validate()
 143            |> Ecto.Changeset.apply_action(:insert) do
 144       update_activity = stringify_keys(update_activity)
 145       {:ok, update_activity, meta}
 146     else
 147       {:local, _} ->
 148         with {:ok, object} <-
 149                update_activity
 150                |> UpdateValidator.cast_and_validate()
 151                |> Ecto.Changeset.apply_action(:insert) do
 152           object = stringify_keys(object)
 153           {:ok, object, meta}
 154         end
 155
 156       {:object_validation, e} ->
 157         e
 158     end
 159   end
 160
 161   def validate(%{"type" => type} = object, meta)
 162       when type in ~w[Accept Reject Follow Update Like EmojiReact Announce
 163       Answer] do
 164     validator =
 165       case type do
 166         "Accept" -> AcceptRejectValidator
 167         "Reject" -> AcceptRejectValidator
 168         "Follow" -> FollowValidator
 169         "Update" -> UpdateValidator
 170         "Like" -> LikeValidator
 171         "EmojiReact" -> EmojiReactValidator
 172         "Announce" -> AnnounceValidator
 173         "Answer" -> AnswerValidator
 174       end
 175
 176     with {:ok, object} <-
 177            object
 178            |> validator.cast_and_validate()
 179            |> Ecto.Changeset.apply_action(:insert) do
 180       object = stringify_keys(object)
 181       {:ok, object, meta}
 182     end
 183   end
 184
 185   def validate(%{"type" => type} = object, meta) when type in ~w(Add Remove) do
 186     with {:ok, object} <-
 187            object
 188            |> AddRemoveValidator.cast_and_validate()
 189            |> Ecto.Changeset.apply_action(:insert) do
 190       object = stringify_keys(object)
 191       {:ok, object, meta}
 192     end
 193   end
 194
 195   def validate(o, m), do: {:error, {:validator_not_set, {o, m}}}
 196
 197   def cast_and_apply_and_stringify_with_history(object) do
 198     do_separate_with_history(object, fn object ->
 199       with {:ok, object_data} <- cast_and_apply(object),
 200            object_data <- object_data |> stringify_keys() do
 201         {:ok, object_data}
 202       end
 203     end)
 204   end
 205
 206   def cast_and_apply(%{"type" => "Question"} = object) do
 207     QuestionValidator.cast_and_apply(object)
 208   end
 209
 210   def cast_and_apply(%{"type" => "Answer"} = object) do
 211     AnswerValidator.cast_and_apply(object)
 212   end
 213
 214   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 215     AudioVideoValidator.cast_and_apply(object)
 216   end
 217
 218   def cast_and_apply(%{"type" => "Event"} = object) do
 219     EventValidator.cast_and_apply(object)
 220   end
 221
 222   def cast_and_apply(%{"type" => type} = object) when type in ~w[Article Note Page] do
 223     ArticleNotePageValidator.cast_and_apply(object)
 224   end
 225
 226   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 227
 228   # is_struct/1 appears in Elixir 1.11
 229   def stringify_keys(%{__struct__: _} = object) do
 230     object
 231     |> Map.from_struct()
 232     |> stringify_keys
 233   end
 234
 235   def stringify_keys(object) when is_map(object) do
 236     object
 237     |> Enum.filter(fn {_, v} -> v != nil end)
 238     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 239   end
 240
 241   def stringify_keys(object) when is_list(object) do
 242     object
 243     |> Enum.map(&stringify_keys/1)
 244   end
 245
 246   def stringify_keys(object), do: object
 247
 248   def fetch_actor(object) do
 249     with actor <- Containment.get_actor(object),
 250          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 251       User.get_or_fetch_by_ap_id(actor)
 252     end
 253   end
 254
 255   def fetch_actor_and_object(object) do
 256     fetch_actor(object)
 257     Object.normalize(object["object"], fetch: true)
 258     :ok
 259   end
 260
 261   defp for_each_history_item(
 262          %{"type" => "OrderedCollection", "orderedItems" => items} = history,
 263          object,
 264          fun
 265        ) do
 266     processed_items =
 267       Enum.map(items, fn item ->
 268         with item <- Map.put(item, "id", object["id"]),
 269              {:ok, item} <- fun.(item) do
 270           item
 271         else
 272           _ -> nil
 273         end
 274       end)
 275
 276     if Enum.all?(processed_items, &(not is_nil(&1))) do
 277       {:ok, Map.put(history, "orderedItems", processed_items)}
 278     else
 279       {:error, :invalid_history}
 280     end
 281   end
 282
 283   defp for_each_history_item(nil, _object, _fun) do
 284     {:ok, nil}
 285   end
 286
 287   defp for_each_history_item(_, _object, _fun) do
 288     {:error, :invalid_history}
 289   end
 290
 291   # fun is (object -> {:ok, validated_object_with_string_keys})
 292   defp do_separate_with_history(object, fun) do
 293     with history <- object["formerRepresentations"],
 294          object <- Map.drop(object, ["formerRepresentations"]),
 295          {_, {:ok, object}} <- {:main_body, fun.(object)},
 296          {_, {:ok, history}} <- {:history_items, for_each_history_item(history, object, fun)} do
 297       object =
 298         if history do
 299           Map.put(object, "formerRepresentations", history)
 300         else
 301           object
 302         end
 303
 304       {:ok, object}
 305     else
 306       {:main_body, e} -> e
 307       {:history_items, e} -> e
 308     end
 309   end
 310 end