git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  17
  18   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  19   def validate(object, meta)
  20
  21   def validate(%{"type" => "Like"} = object, meta) do
  22     with {:ok, object} <-
  23            object
  24            |> LikeValidator.cast_and_validate()
  25            |> Ecto.Changeset.apply_action(:insert) do
  26       object = stringify_keys(object)
  27       {:ok, object, meta}
  28     end
  29   end
  30
  31   def validate(%{"type" => "ChatMessage"} = object, meta) do
  32     with {:ok, object} <-
  33            object
  34            |> ChatMessageValidator.cast_and_validate()
  35            |> Ecto.Changeset.apply_action(:insert) do
  36       object = stringify_keys(object)
  37       {:ok, object, meta}
  38     end
  39   end
  40
  41   def validate(%{"type" => "Create", "object" => object} = create_activity, meta) do
  42     with {:ok, object_data} <- cast_and_apply(object),
  43          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  44          {:ok, create_activity} <-
  45            create_activity
  46            |> CreateChatMessageValidator.cast_and_validate(meta)
  47            |> Ecto.Changeset.apply_action(:insert) do
  48       create_activity = stringify_keys(create_activity)
  49       {:ok, create_activity, meta}
  50     end
  51   end
  52
  53   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
  54     ChatMessageValidator.cast_and_apply(object)
  55   end
  56
  57   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
  58
  59   def stringify_keys(%{__struct__: _} = object) do
  60     object
  61     |> Map.from_struct()
  62     |> stringify_keys
  63   end
  64
  65   def stringify_keys(object) do
  66     object
  67     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  68   end
  69
  70   def fetch_actor_and_object(object) do
  71     User.get_or_fetch_by_ap_id(object["actor"])
  72     Object.normalize(object["object"])
  73     :ok
  74   end
  75 end