git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  13   alias Pleroma.Object
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  24
  25   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  26   def validate(object, meta)
  27
  28   def validate(%{"type" => "Block"} = block_activity, meta) do
  29     with {:ok, block_activity} <-
  30            block_activity
  31            |> BlockValidator.cast_and_validate()
  32            |> Ecto.Changeset.apply_action(:insert) do
  33       block_activity = stringify_keys(block_activity)
  34       {:ok, block_activity, meta}
  35     end
  36   end
  37
  38   def validate(%{"type" => "Update"} = update_activity, meta) do
  39     with {:ok, update_activity} <-
  40            update_activity
  41            |> UpdateValidator.cast_and_validate()
  42            |> Ecto.Changeset.apply_action(:insert) do
  43       update_activity = stringify_keys(update_activity)
  44       {:ok, update_activity, meta}
  45     end
  46   end
  47
  48   def validate(%{"type" => "Undo"} = object, meta) do
  49     with {:ok, object} <-
  50            object
  51            |> UndoValidator.cast_and_validate()
  52            |> Ecto.Changeset.apply_action(:insert) do
  53       object = stringify_keys(object)
  54       {:ok, object, meta}
  55     end
  56   end
  57
  58   def validate(%{"type" => "Delete"} = object, meta) do
  59     with cng <- DeleteValidator.cast_and_validate(object),
  60          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  61          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  62       object = stringify_keys(object)
  63       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  64       {:ok, object, meta}
  65     end
  66   end
  67
  68   def validate(%{"type" => "Like"} = object, meta) do
  69     with {:ok, object} <-
  70            object
  71            |> LikeValidator.cast_and_validate()
  72            |> Ecto.Changeset.apply_action(:insert) do
  73       object = stringify_keys(object)
  74       {:ok, object, meta}
  75     end
  76   end
  77
  78   def validate(%{"type" => "ChatMessage"} = object, meta) do
  79     with {:ok, object} <-
  80            object
  81            |> ChatMessageValidator.cast_and_validate()
  82            |> Ecto.Changeset.apply_action(:insert) do
  83       object = stringify_keys(object)
  84       {:ok, object, meta}
  85     end
  86   end
  87
  88   def validate(%{"type" => "EmojiReact"} = object, meta) do
  89     with {:ok, object} <-
  90            object
  91            |> EmojiReactValidator.cast_and_validate()
  92            |> Ecto.Changeset.apply_action(:insert) do
  93       object = stringify_keys(object |> Map.from_struct())
  94       {:ok, object, meta}
  95     end
  96   end
  97
  98   def validate(%{"type" => "Create", "object" => object} = create_activity, meta) do
  99     with {:ok, object_data} <- cast_and_apply(object),
 100          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 101          {:ok, create_activity} <-
 102            create_activity
 103            |> CreateChatMessageValidator.cast_and_validate(meta)
 104            |> Ecto.Changeset.apply_action(:insert) do
 105       create_activity = stringify_keys(create_activity)
 106       {:ok, create_activity, meta}
 107     end
 108   end
 109
 110   def validate(%{"type" => "Announce"} = object, meta) do
 111     with {:ok, object} <-
 112            object
 113            |> AnnounceValidator.cast_and_validate()
 114            |> Ecto.Changeset.apply_action(:insert) do
 115       object = stringify_keys(object |> Map.from_struct())
 116       {:ok, object, meta}
 117     end
 118   end
 119
 120   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 121     ChatMessageValidator.cast_and_apply(object)
 122   end
 123
 124   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 125
 126   def stringify_keys(%{__struct__: _} = object) do
 127     object
 128     |> Map.from_struct()
 129     |> stringify_keys
 130   end
 131
 132   def stringify_keys(object) when is_map(object) do
 133     object
 134     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 135   end
 136
 137   def stringify_keys(object) when is_list(object) do
 138     object
 139     |> Enum.map(&stringify_keys/1)
 140   end
 141
 142   def stringify_keys(object), do: object
 143
 144   def fetch_actor(object) do
 145     with {:ok, actor} <- ObjectValidators.ObjectID.cast(object["actor"]) do
 146       User.get_or_fetch_by_ap_id(actor)
 147     end
 148   end
 149
 150   def fetch_actor_and_object(object) do
 151     fetch_actor(object)
 152     Object.normalize(object["object"], true)
 153     :ok
 154   end
 155 end