git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNoteValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  35   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  36
  37   @impl true
  38   def validate(object, meta)
  39
  40   def validate(%{"type" => "Block"} = block_activity, meta) do
  41     with {:ok, block_activity} <-
  42            block_activity
  43            |> BlockValidator.cast_and_validate()
  44            |> Ecto.Changeset.apply_action(:insert) do
  45       block_activity = stringify_keys(block_activity)
  46       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  47
  48       meta =
  49         if !outgoing_blocks do
  50           Keyword.put(meta, :do_not_federate, true)
  51         else
  52           meta
  53         end
  54
  55       {:ok, block_activity, meta}
  56     end
  57   end
  58
  59   def validate(%{"type" => "Undo"} = object, meta) do
  60     with {:ok, object} <-
  61            object
  62            |> UndoValidator.cast_and_validate()
  63            |> Ecto.Changeset.apply_action(:insert) do
  64       object = stringify_keys(object)
  65       undone_object = Activity.get_by_ap_id(object["object"])
  66
  67       meta =
  68         meta
  69         |> Keyword.put(:object_data, undone_object.data)
  70
  71       {:ok, object, meta}
  72     end
  73   end
  74
  75   def validate(%{"type" => "Delete"} = object, meta) do
  76     with cng <- DeleteValidator.cast_and_validate(object),
  77          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  78          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  79       object = stringify_keys(object)
  80       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  81       {:ok, object, meta}
  82     end
  83   end
  84
  85   def validate(
  86         %{"type" => "Create", "object" => %{"type" => "ChatMessage"} = object} = create_activity,
  87         meta
  88       ) do
  89     with {:ok, object_data} <- cast_and_apply(object),
  90          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  91          {:ok, create_activity} <-
  92            create_activity
  93            |> CreateChatMessageValidator.cast_and_validate(meta)
  94            |> Ecto.Changeset.apply_action(:insert) do
  95       create_activity = stringify_keys(create_activity)
  96       {:ok, create_activity, meta}
  97     end
  98   end
  99
 100   def validate(
 101         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
 102         meta
 103       )
 104       when objtype in ~w[Question Answer Audio Video Event Article] do
 105     with {:ok, object_data} <- cast_and_apply(object),
 106          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 107          {:ok, create_activity} <-
 108            create_activity
 109            |> CreateGenericValidator.cast_and_validate(meta)
 110            |> Ecto.Changeset.apply_action(:insert) do
 111       create_activity = stringify_keys(create_activity)
 112       {:ok, create_activity, meta}
 113     end
 114   end
 115
 116   def validate(%{"type" => type} = object, meta)
 117       when type in ~w[Event Question Audio Video Article] do
 118     validator =
 119       case type do
 120         "Event" -> EventValidator
 121         "Question" -> QuestionValidator
 122         "Audio" -> AudioVideoValidator
 123         "Video" -> AudioVideoValidator
 124         "Article" -> ArticleNoteValidator
 125       end
 126
 127     with {:ok, object} <-
 128            object
 129            |> validator.cast_and_validate()
 130            |> Ecto.Changeset.apply_action(:insert) do
 131       object = stringify_keys(object)
 132
 133       # Insert copy of hashtags as strings for the non-hashtag table indexing
 134       tag = (object["tag"] || []) ++ Object.hashtags(%Object{data: object})
 135       object = Map.put(object, "tag", tag)
 136
 137       {:ok, object, meta}
 138     end
 139   end
 140
 141   def validate(%{"type" => type} = object, meta)
 142       when type in ~w[Accept Reject Follow Update Like EmojiReact Announce
 143       ChatMessage Answer] do
 144     validator =
 145       case type do
 146         "Accept" -> AcceptRejectValidator
 147         "Reject" -> AcceptRejectValidator
 148         "Follow" -> FollowValidator
 149         "Update" -> UpdateValidator
 150         "Like" -> LikeValidator
 151         "EmojiReact" -> EmojiReactValidator
 152         "Announce" -> AnnounceValidator
 153         "ChatMessage" -> ChatMessageValidator
 154         "Answer" -> AnswerValidator
 155       end
 156
 157     with {:ok, object} <-
 158            object
 159            |> validator.cast_and_validate()
 160            |> Ecto.Changeset.apply_action(:insert) do
 161       object = stringify_keys(object)
 162       {:ok, object, meta}
 163     end
 164   end
 165
 166   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 167     ChatMessageValidator.cast_and_apply(object)
 168   end
 169
 170   def cast_and_apply(%{"type" => "Question"} = object) do
 171     QuestionValidator.cast_and_apply(object)
 172   end
 173
 174   def cast_and_apply(%{"type" => "Answer"} = object) do
 175     AnswerValidator.cast_and_apply(object)
 176   end
 177
 178   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 179     AudioVideoValidator.cast_and_apply(object)
 180   end
 181
 182   def cast_and_apply(%{"type" => "Event"} = object) do
 183     EventValidator.cast_and_apply(object)
 184   end
 185
 186   def cast_and_apply(%{"type" => "Article"} = object) do
 187     ArticleNoteValidator.cast_and_apply(object)
 188   end
 189
 190   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 191
 192   # is_struct/1 appears in Elixir 1.11
 193   def stringify_keys(%{__struct__: _} = object) do
 194     object
 195     |> Map.from_struct()
 196     |> stringify_keys
 197   end
 198
 199   def stringify_keys(object) when is_map(object) do
 200     object
 201     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 202   end
 203
 204   def stringify_keys(object) when is_list(object) do
 205     object
 206     |> Enum.map(&stringify_keys/1)
 207   end
 208
 209   def stringify_keys(object), do: object
 210
 211   def fetch_actor(object) do
 212     with actor <- Containment.get_actor(object),
 213          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 214       User.get_or_fetch_by_ap_id(actor)
 215     end
 216   end
 217
 218   def fetch_actor_and_object(object) do
 219     fetch_actor(object)
 220     Object.normalize(object["object"], fetch: true)
 221     :ok
 222   end
 223 end