git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AddRemoveValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNoteValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  35   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  36   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  37
  38   @impl true
  39   def validate(object, meta)
  40
  41   def validate(%{"type" => "Block"} = block_activity, meta) do
  42     with {:ok, block_activity} <-
  43            block_activity
  44            |> BlockValidator.cast_and_validate()
  45            |> Ecto.Changeset.apply_action(:insert) do
  46       block_activity = stringify_keys(block_activity)
  47       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  48
  49       meta =
  50         if !outgoing_blocks do
  51           Keyword.put(meta, :do_not_federate, true)
  52         else
  53           meta
  54         end
  55
  56       {:ok, block_activity, meta}
  57     end
  58   end
  59
  60   def validate(%{"type" => "Undo"} = object, meta) do
  61     with {:ok, object} <-
  62            object
  63            |> UndoValidator.cast_and_validate()
  64            |> Ecto.Changeset.apply_action(:insert) do
  65       object = stringify_keys(object)
  66       undone_object = Activity.get_by_ap_id(object["object"])
  67
  68       meta =
  69         meta
  70         |> Keyword.put(:object_data, undone_object.data)
  71
  72       {:ok, object, meta}
  73     end
  74   end
  75
  76   def validate(%{"type" => "Delete"} = object, meta) do
  77     with cng <- DeleteValidator.cast_and_validate(object),
  78          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  79          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  80       object = stringify_keys(object)
  81       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  82       {:ok, object, meta}
  83     end
  84   end
  85
  86   def validate(
  87         %{"type" => "Create", "object" => %{"type" => "ChatMessage"} = object} = create_activity,
  88         meta
  89       ) do
  90     with {:ok, object_data} <- cast_and_apply(object),
  91          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  92          {:ok, create_activity} <-
  93            create_activity
  94            |> CreateChatMessageValidator.cast_and_validate(meta)
  95            |> Ecto.Changeset.apply_action(:insert) do
  96       create_activity = stringify_keys(create_activity)
  97       {:ok, create_activity, meta}
  98     end
  99   end
 100
 101   def validate(
 102         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
 103         meta
 104       )
 105       when objtype in ~w[Question Answer Audio Video Event Article Note] do
 106     with {:ok, object_data} <- cast_and_apply(object),
 107          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 108          {:ok, create_activity} <-
 109            create_activity
 110            |> CreateGenericValidator.cast_and_validate(meta)
 111            |> Ecto.Changeset.apply_action(:insert) do
 112       create_activity = stringify_keys(create_activity)
 113       {:ok, create_activity, meta}
 114     end
 115   end
 116
 117   def validate(%{"type" => type} = object, meta)
 118       when type in ~w[Event Question Audio Video Article Note] do
 119     validator =
 120       case type do
 121         "Event" -> EventValidator
 122         "Question" -> QuestionValidator
 123         "Audio" -> AudioVideoValidator
 124         "Video" -> AudioVideoValidator
 125         "Article" -> ArticleNoteValidator
 126         "Note" -> ArticleNoteValidator
 127       end
 128
 129     with {:ok, object} <-
 130            object
 131            |> validator.cast_and_validate()
 132            |> Ecto.Changeset.apply_action(:insert) do
 133       object = stringify_keys(object)
 134
 135       # Insert copy of hashtags as strings for the non-hashtag table indexing
 136       tag = (object["tag"] || []) ++ Object.hashtags(%Object{data: object})
 137       object = Map.put(object, "tag", tag)
 138
 139       {:ok, object, meta}
 140     end
 141   end
 142
 143   def validate(%{"type" => type} = object, meta)
 144       when type in ~w[Accept Reject Follow Update Like EmojiReact Announce
 145       ChatMessage Answer] do
 146     validator =
 147       case type do
 148         "Accept" -> AcceptRejectValidator
 149         "Reject" -> AcceptRejectValidator
 150         "Follow" -> FollowValidator
 151         "Update" -> UpdateValidator
 152         "Like" -> LikeValidator
 153         "EmojiReact" -> EmojiReactValidator
 154         "Announce" -> AnnounceValidator
 155         "ChatMessage" -> ChatMessageValidator
 156         "Answer" -> AnswerValidator
 157       end
 158
 159     with {:ok, object} <-
 160            object
 161            |> validator.cast_and_validate()
 162            |> Ecto.Changeset.apply_action(:insert) do
 163       object = stringify_keys(object)
 164       {:ok, object, meta}
 165     end
 166   end
 167
 168   def validate(%{"type" => type} = object, meta) when type in ~w(Add Remove) do
 169     with {:ok, object} <-
 170            object
 171            |> AddRemoveValidator.cast_and_validate()
 172            |> Ecto.Changeset.apply_action(:insert) do
 173       object = stringify_keys(object)
 174       {:ok, object, meta}
 175     end
 176   end
 177
 178   def validate(o, m), do: {:error, {:validator_not_set, {o, m}}}
 179
 180   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 181     ChatMessageValidator.cast_and_apply(object)
 182   end
 183
 184   def cast_and_apply(%{"type" => "Question"} = object) do
 185     QuestionValidator.cast_and_apply(object)
 186   end
 187
 188   def cast_and_apply(%{"type" => "Answer"} = object) do
 189     AnswerValidator.cast_and_apply(object)
 190   end
 191
 192   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 193     AudioVideoValidator.cast_and_apply(object)
 194   end
 195
 196   def cast_and_apply(%{"type" => "Event"} = object) do
 197     EventValidator.cast_and_apply(object)
 198   end
 199
 200   def cast_and_apply(%{"type" => type} = object) when type in ~w[Article Note] do
 201     ArticleNoteValidator.cast_and_apply(object)
 202   end
 203
 204   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 205
 206   # is_struct/1 appears in Elixir 1.11
 207   def stringify_keys(%{__struct__: _} = object) do
 208     object
 209     |> Map.from_struct()
 210     |> stringify_keys
 211   end
 212
 213   def stringify_keys(object) when is_map(object) do
 214     object
 215     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 216   end
 217
 218   def stringify_keys(object) when is_list(object) do
 219     object
 220     |> Enum.map(&stringify_keys/1)
 221   end
 222
 223   def stringify_keys(object), do: object
 224
 225   def fetch_actor(object) do
 226     with actor <- Containment.get_actor(object),
 227          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 228       User.get_or_fetch_by_ap_id(actor)
 229     end
 230   end
 231
 232   def fetch_actor_and_object(object) do
 233     fetch_actor(object)
 234     Object.normalize(object["object"], fetch: true)
 235     :ok
 236   end
 237 end