git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNoteValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  35   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  36
  37   @impl true
  38   def validate(object, meta)
  39
  40   def validate(%{"type" => type} = object, meta)
  41       when type in ~w[Accept Reject] do
  42     with {:ok, object} <-
  43            object
  44            |> AcceptRejectValidator.cast_and_validate()
  45            |> Ecto.Changeset.apply_action(:insert) do
  46       object = stringify_keys(object)
  47       {:ok, object, meta}
  48     end
  49   end
  50
  51   def validate(%{"type" => "Event"} = object, meta) do
  52     with {:ok, object} <-
  53            object
  54            |> EventValidator.cast_and_validate()
  55            |> Ecto.Changeset.apply_action(:insert) do
  56       object = stringify_keys(object)
  57       {:ok, object, meta}
  58     end
  59   end
  60
  61   def validate(%{"type" => "Follow"} = object, meta) do
  62     with {:ok, object} <-
  63            object
  64            |> FollowValidator.cast_and_validate()
  65            |> Ecto.Changeset.apply_action(:insert) do
  66       object = stringify_keys(object)
  67       {:ok, object, meta}
  68     end
  69   end
  70
  71   def validate(%{"type" => "Block"} = block_activity, meta) do
  72     with {:ok, block_activity} <-
  73            block_activity
  74            |> BlockValidator.cast_and_validate()
  75            |> Ecto.Changeset.apply_action(:insert) do
  76       block_activity = stringify_keys(block_activity)
  77       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  78
  79       meta =
  80         if !outgoing_blocks do
  81           Keyword.put(meta, :do_not_federate, true)
  82         else
  83           meta
  84         end
  85
  86       {:ok, block_activity, meta}
  87     end
  88   end
  89
  90   def validate(%{"type" => "Update"} = update_activity, meta) do
  91     with {:ok, update_activity} <-
  92            update_activity
  93            |> UpdateValidator.cast_and_validate()
  94            |> Ecto.Changeset.apply_action(:insert) do
  95       update_activity = stringify_keys(update_activity)
  96       {:ok, update_activity, meta}
  97     end
  98   end
  99
 100   def validate(%{"type" => "Undo"} = object, meta) do
 101     with {:ok, object} <-
 102            object
 103            |> UndoValidator.cast_and_validate()
 104            |> Ecto.Changeset.apply_action(:insert) do
 105       object = stringify_keys(object)
 106       undone_object = Activity.get_by_ap_id(object["object"])
 107
 108       meta =
 109         meta
 110         |> Keyword.put(:object_data, undone_object.data)
 111
 112       {:ok, object, meta}
 113     end
 114   end
 115
 116   def validate(%{"type" => "Delete"} = object, meta) do
 117     with cng <- DeleteValidator.cast_and_validate(object),
 118          do_not_federate <- DeleteValidator.do_not_federate?(cng),
 119          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
 120       object = stringify_keys(object)
 121       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
 122       {:ok, object, meta}
 123     end
 124   end
 125
 126   def validate(%{"type" => "Like"} = object, meta) do
 127     with {:ok, object} <-
 128            object
 129            |> LikeValidator.cast_and_validate()
 130            |> Ecto.Changeset.apply_action(:insert) do
 131       object = stringify_keys(object)
 132       {:ok, object, meta}
 133     end
 134   end
 135
 136   def validate(%{"type" => "ChatMessage"} = object, meta) do
 137     with {:ok, object} <-
 138            object
 139            |> ChatMessageValidator.cast_and_validate()
 140            |> Ecto.Changeset.apply_action(:insert) do
 141       object = stringify_keys(object)
 142       {:ok, object, meta}
 143     end
 144   end
 145
 146   def validate(%{"type" => "Question"} = object, meta) do
 147     with {:ok, object} <-
 148            object
 149            |> QuestionValidator.cast_and_validate()
 150            |> Ecto.Changeset.apply_action(:insert) do
 151       object = stringify_keys(object)
 152       {:ok, object, meta}
 153     end
 154   end
 155
 156   def validate(%{"type" => type} = object, meta) when type in ~w[Audio Video] do
 157     with {:ok, object} <-
 158            object
 159            |> AudioVideoValidator.cast_and_validate()
 160            |> Ecto.Changeset.apply_action(:insert) do
 161       object = stringify_keys(object)
 162       {:ok, object, meta}
 163     end
 164   end
 165
 166   def validate(%{"type" => "Article"} = object, meta) do
 167     with {:ok, object} <-
 168            object
 169            |> ArticleNoteValidator.cast_and_validate()
 170            |> Ecto.Changeset.apply_action(:insert) do
 171       object = stringify_keys(object)
 172       {:ok, object, meta}
 173     end
 174   end
 175
 176   def validate(%{"type" => "Answer"} = object, meta) do
 177     with {:ok, object} <-
 178            object
 179            |> AnswerValidator.cast_and_validate()
 180            |> Ecto.Changeset.apply_action(:insert) do
 181       object = stringify_keys(object)
 182       {:ok, object, meta}
 183     end
 184   end
 185
 186   def validate(%{"type" => "EmojiReact"} = object, meta) do
 187     with {:ok, object} <-
 188            object
 189            |> EmojiReactValidator.cast_and_validate()
 190            |> Ecto.Changeset.apply_action(:insert) do
 191       object = stringify_keys(object)
 192       {:ok, object, meta}
 193     end
 194   end
 195
 196   def validate(
 197         %{"type" => "Create", "object" => %{"type" => "ChatMessage"} = object} = create_activity,
 198         meta
 199       ) do
 200     with {:ok, object_data} <- cast_and_apply(object),
 201          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 202          {:ok, create_activity} <-
 203            create_activity
 204            |> CreateChatMessageValidator.cast_and_validate(meta)
 205            |> Ecto.Changeset.apply_action(:insert) do
 206       create_activity = stringify_keys(create_activity)
 207       {:ok, create_activity, meta}
 208     end
 209   end
 210
 211   def validate(
 212         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
 213         meta
 214       )
 215       when objtype in ~w[Question Answer Audio Video Event Article] do
 216     with {:ok, object_data} <- cast_and_apply(object),
 217          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 218          {:ok, create_activity} <-
 219            create_activity
 220            |> CreateGenericValidator.cast_and_validate(meta)
 221            |> Ecto.Changeset.apply_action(:insert) do
 222       create_activity = stringify_keys(create_activity)
 223       {:ok, create_activity, meta}
 224     end
 225   end
 226
 227   def validate(%{"type" => "Announce"} = object, meta) do
 228     with {:ok, object} <-
 229            object
 230            |> AnnounceValidator.cast_and_validate()
 231            |> Ecto.Changeset.apply_action(:insert) do
 232       object = stringify_keys(object)
 233       {:ok, object, meta}
 234     end
 235   end
 236
 237   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 238     ChatMessageValidator.cast_and_apply(object)
 239   end
 240
 241   def cast_and_apply(%{"type" => "Question"} = object) do
 242     QuestionValidator.cast_and_apply(object)
 243   end
 244
 245   def cast_and_apply(%{"type" => "Answer"} = object) do
 246     AnswerValidator.cast_and_apply(object)
 247   end
 248
 249   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 250     AudioVideoValidator.cast_and_apply(object)
 251   end
 252
 253   def cast_and_apply(%{"type" => "Event"} = object) do
 254     EventValidator.cast_and_apply(object)
 255   end
 256
 257   def cast_and_apply(%{"type" => "Article"} = object) do
 258     ArticleNoteValidator.cast_and_apply(object)
 259   end
 260
 261   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 262
 263   # is_struct/1 isn't present in Elixir 1.8.x
 264   def stringify_keys(%{__struct__: _} = object) do
 265     object
 266     |> Map.from_struct()
 267     |> stringify_keys
 268   end
 269
 270   def stringify_keys(object) when is_map(object) do
 271     object
 272     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 273   end
 274
 275   def stringify_keys(object) when is_list(object) do
 276     object
 277     |> Enum.map(&stringify_keys/1)
 278   end
 279
 280   def stringify_keys(object), do: object
 281
 282   def fetch_actor(object) do
 283     with actor <- Containment.get_actor(object),
 284          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 285       User.get_or_fetch_by_ap_id(actor)
 286     end
 287   end
 288
 289   def fetch_actor_and_object(object) do
 290     fetch_actor(object)
 291     Object.normalize(object["object"], fetch: true)
 292     :ok
 293   end
 294 end