git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  18
  19   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  20   def validate(object, meta)
  21
  22   def validate(%{"type" => "Like"} = object, meta) do
  23     with {:ok, object} <-
  24            object
  25            |> LikeValidator.cast_and_validate()
  26            |> Ecto.Changeset.apply_action(:insert) do
  27       object = stringify_keys(object)
  28       {:ok, object, meta}
  29     end
  30   end
  31
  32   def validate(%{"type" => "ChatMessage"} = object, meta) do
  33     with {:ok, object} <-
  34            object
  35            |> ChatMessageValidator.cast_and_validate()
  36            |> Ecto.Changeset.apply_action(:insert) do
  37       object = stringify_keys(object)
  38       {:ok, object, meta}
  39     end
  40   end
  41
  42   def validate(%{"type" => "Create", "object" => object} = create_activity, meta) do
  43     with {:ok, object_data} <- cast_and_apply(object),
  44          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  45          {:ok, create_activity} <-
  46            create_activity
  47            |> CreateChatMessageValidator.cast_and_validate(meta)
  48            |> Ecto.Changeset.apply_action(:insert) do
  49       create_activity = stringify_keys(create_activity)
  50       {:ok, create_activity, meta}
  51     end
  52   end
  53
  54   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
  55     ChatMessageValidator.cast_and_apply(object)
  56   end
  57
  58   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
  59
  60   def stringify_keys(%{__struct__: _} = object) do
  61     object
  62     |> Map.from_struct()
  63     |> stringify_keys
  64   end
  65
  66   def stringify_keys(object) do
  67     object
  68     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  69   end
  70
  71   def fetch_actor(object) do
  72     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
  73       User.get_or_fetch_by_ap_id(actor)
  74     end
  75   end
  76
  77   def fetch_actor_and_object(object) do
  78     fetch_actor(object)
  79     Object.normalize(object["object"])
  80     :ok
  81   end
  82 end