git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNoteValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  35   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  36
  37   @impl true
  38   def validate(object, meta)
  39
  40   def validate(%{"type" => "Block"} = block_activity, meta) do
  41     with {:ok, block_activity} <-
  42            block_activity
  43            |> BlockValidator.cast_and_validate()
  44            |> Ecto.Changeset.apply_action(:insert) do
  45       block_activity = stringify_keys(block_activity)
  46       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  47
  48       meta =
  49         if !outgoing_blocks do
  50           Keyword.put(meta, :do_not_federate, true)
  51         else
  52           meta
  53         end
  54
  55       {:ok, block_activity, meta}
  56     end
  57   end
  58
  59   def validate(%{"type" => "Undo"} = object, meta) do
  60     with {:ok, object} <-
  61            object
  62            |> UndoValidator.cast_and_validate()
  63            |> Ecto.Changeset.apply_action(:insert) do
  64       object = stringify_keys(object)
  65       undone_object = Activity.get_by_ap_id(object["object"])
  66
  67       meta =
  68         meta
  69         |> Keyword.put(:object_data, undone_object.data)
  70
  71       {:ok, object, meta}
  72     end
  73   end
  74
  75   def validate(%{"type" => "Delete"} = object, meta) do
  76     with cng <- DeleteValidator.cast_and_validate(object),
  77          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  78          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  79       object = stringify_keys(object)
  80       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  81       {:ok, object, meta}
  82     end
  83   end
  84
  85   def validate(
  86         %{"type" => "Create", "object" => %{"type" => "ChatMessage"} = object} = create_activity,
  87         meta
  88       ) do
  89     with {:ok, object_data} <- cast_and_apply(object),
  90          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  91          {:ok, create_activity} <-
  92            create_activity
  93            |> CreateChatMessageValidator.cast_and_validate(meta)
  94            |> Ecto.Changeset.apply_action(:insert) do
  95       create_activity = stringify_keys(create_activity)
  96       {:ok, create_activity, meta}
  97     end
  98   end
  99
 100   def validate(
 101         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
 102         meta
 103       )
 104       when objtype in ~w[Question Answer Audio Video Event Article] do
 105     with {:ok, object_data} <- cast_and_apply(object),
 106          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
 107          {:ok, create_activity} <-
 108            create_activity
 109            |> CreateGenericValidator.cast_and_validate(meta)
 110            |> Ecto.Changeset.apply_action(:insert) do
 111       create_activity = stringify_keys(create_activity)
 112       {:ok, create_activity, meta}
 113     end
 114   end
 115
 116   def validate(%{"type" => type} = object, meta)
 117       when type in ~w[Accept Reject Follow Update Like EmojiReact Announce
 118       Event ChatMessage Question Audio Video Article Answer] do
 119     validator =
 120       case type do
 121         "Accept" -> AcceptRejectValidator
 122         "Reject" -> AcceptRejectValidator
 123         "Follow" -> FollowValidator
 124         "Update" -> UpdateValidator
 125         "Like" -> LikeValidator
 126         "EmojiReact" -> EmojiReactValidator
 127         "Announce" -> AnnounceValidator
 128         "Event" -> EventValidator
 129         "ChatMessage" -> ChatMessageValidator
 130         "Question" -> QuestionValidator
 131         "Audio" -> AudioVideoValidator
 132         "Video" -> AudioVideoValidator
 133         "Article" -> ArticleNoteValidator
 134         "Answer" -> AnswerValidator
 135       end
 136
 137     with {:ok, object} <-
 138            object
 139            |> validator.cast_and_validate()
 140            |> Ecto.Changeset.apply_action(:insert) do
 141       object = stringify_keys(object)
 142       {:ok, object, meta}
 143     end
 144   end
 145
 146   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
 147     ChatMessageValidator.cast_and_apply(object)
 148   end
 149
 150   def cast_and_apply(%{"type" => "Question"} = object) do
 151     QuestionValidator.cast_and_apply(object)
 152   end
 153
 154   def cast_and_apply(%{"type" => "Answer"} = object) do
 155     AnswerValidator.cast_and_apply(object)
 156   end
 157
 158   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 159     AudioVideoValidator.cast_and_apply(object)
 160   end
 161
 162   def cast_and_apply(%{"type" => "Event"} = object) do
 163     EventValidator.cast_and_apply(object)
 164   end
 165
 166   def cast_and_apply(%{"type" => "Article"} = object) do
 167     ArticleNoteValidator.cast_and_apply(object)
 168   end
 169
 170   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 171
 172   # is_struct/1 appears in Elixir 1.11
 173   def stringify_keys(%{__struct__: _} = object) do
 174     object
 175     |> Map.from_struct()
 176     |> stringify_keys
 177   end
 178
 179   def stringify_keys(object) when is_map(object) do
 180     object
 181     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 182   end
 183
 184   def stringify_keys(object) when is_list(object) do
 185     object
 186     |> Enum.map(&stringify_keys/1)
 187   end
 188
 189   def stringify_keys(object), do: object
 190
 191   def fetch_actor(object) do
 192     with actor <- Containment.get_actor(object),
 193          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 194       User.get_or_fetch_by_ap_id(actor)
 195     end
 196   end
 197
 198   def fetch_actor_and_object(object) do
 199     fetch_actor(object)
 200     Object.normalize(object["object"], fetch: true)
 201     :ok
 202   end
 203 end