git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF do
   6   require Logger
   7
   8   @behaviour Pleroma.Web.ActivityPub.MRF.PipelineFiltering
   9
  10   @mrf_config_descriptions [
  11     %{
  12       group: :pleroma,
  13       key: :mrf,
  14       tab: :mrf,
  15       label: "MRF",
  16       type: :group,
  17       description: "General MRF settings",
  18       children: [
  19         %{
  20           key: :policies,
  21           type: [:module, {:list, :module}],
  22           description:
  23             "A list of MRF policies enabled. Module names are shortened (removed leading `Pleroma.Web.ActivityPub.MRF.` part), but on adding custom module you need to use full name.",
  24           suggestions: {:list_behaviour_implementations, Pleroma.Web.ActivityPub.MRF}
  25         },
  26         %{
  27           key: :transparency,
  28           label: "MRF transparency",
  29           type: :boolean,
  30           description:
  31             "Make the content of your Message Rewrite Facility settings public (via nodeinfo)"
  32         },
  33         %{
  34           key: :transparency_exclusions,
  35           label: "MRF transparency exclusions",
  36           type: {:list, :string},
  37           description:
  38             "Exclude specific instance names from MRF transparency. The use of the exclusions feature will be disclosed in nodeinfo as a boolean value.",
  39           suggestions: [
  40             "exclusion.com"
  41           ]
  42         }
  43       ]
  44     }
  45   ]
  46
  47   @default_description %{
  48     label: "",
  49     description: ""
  50   }
  51
  52   @required_description_keys [:key, :related_policy]
  53
  54   @callback filter(Map.t()) :: {:ok | :reject, Map.t()}
  55   @callback describe() :: {:ok | :error, Map.t()}
  56   @callback config_description() :: %{
  57               optional(:children) => [map()],
  58               key: atom(),
  59               related_policy: String.t(),
  60               label: String.t(),
  61               description: String.t()
  62             }
  63   @optional_callbacks config_description: 0
  64
  65   def filter(policies, %{} = message) do
  66     policies
  67     |> Enum.reduce({:ok, message}, fn
  68       policy, {:ok, message} -> policy.filter(message)
  69       _, error -> error
  70     end)
  71   end
  72
  73   def filter(%{} = object), do: get_policies() |> filter(object)
  74
  75   @impl true
  76   def pipeline_filter(%{} = message, meta) do
  77     object = meta[:object_data]
  78     ap_id = message["object"]
  79
  80     if object && ap_id do
  81       with {:ok, message} <- filter(Map.put(message, "object", object)) do
  82         meta = Keyword.put(meta, :object_data, message["object"])
  83         {:ok, Map.put(message, "object", ap_id), meta}
  84       else
  85         {err, message} -> {err, message, meta}
  86       end
  87     else
  88       {err, message} = filter(message)
  89
  90       {err, message, meta}
  91     end
  92   end
  93
  94   def get_policies do
  95     Pleroma.Config.get([:mrf, :policies], [])
  96     |> get_policies()
  97     |> Enum.concat([Pleroma.Web.ActivityPub.MRF.HashtagPolicy])
  98   end
  99
 100   defp get_policies(policy) when is_atom(policy), do: [policy]
 101   defp get_policies(policies) when is_list(policies), do: policies
 102   defp get_policies(_), do: []
 103
 104   @spec subdomains_regex([String.t()]) :: [Regex.t()]
 105   def subdomains_regex(domains) when is_list(domains) do
 106     for domain <- domains, do: ~r(^#{String.replace(domain, "*.", "(.*\\.)*")}$)i
 107   end
 108
 109   @spec subdomain_match?([Regex.t()], String.t()) :: boolean()
 110   def subdomain_match?(domains, host) do
 111     Enum.any?(domains, fn domain -> Regex.match?(domain, host) end)
 112   end
 113
 114   def describe(policies) do
 115     {:ok, policy_configs} =
 116       policies
 117       |> Enum.reduce({:ok, %{}}, fn
 118         policy, {:ok, data} ->
 119           {:ok, policy_data} = policy.describe()
 120           {:ok, Map.merge(data, policy_data)}
 121
 122         _, error ->
 123           error
 124       end)
 125
 126     mrf_policies =
 127       get_policies()
 128       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
 129
 130     exclusions = Pleroma.Config.get([:mrf, :transparency_exclusions])
 131
 132     base =
 133       %{
 134         mrf_policies: mrf_policies,
 135         exclusions: length(exclusions) > 0
 136       }
 137       |> Map.merge(policy_configs)
 138
 139     {:ok, base}
 140   end
 141
 142   def describe, do: get_policies() |> describe()
 143
 144   def config_descriptions do
 145     Pleroma.Web.ActivityPub.MRF
 146     |> Pleroma.Docs.Generator.list_behaviour_implementations()
 147     |> config_descriptions()
 148   end
 149
 150   def config_descriptions(policies) do
 151     Enum.reduce(policies, @mrf_config_descriptions, fn policy, acc ->
 152       if function_exported?(policy, :config_description, 0) do
 153         description =
 154           @default_description
 155           |> Map.merge(policy.config_description)
 156           |> Map.put(:group, :pleroma)
 157           |> Map.put(:tab, :mrf)
 158           |> Map.put(:type, :group)
 159
 160         if Enum.all?(@required_description_keys, &Map.has_key?(description, &1)) do
 161           [description | acc]
 162         else
 163           Logger.warn(
 164             "#{policy} config description doesn't have one or all required keys #{
 165               inspect(@required_description_keys)
 166             }"
 167           )
 168
 169           acc
 170         end
 171       else
 172         Logger.debug(
 173           "#{policy} is excluded from config descriptions, because does not implement `config_description/0` method."
 174         )
 175
 176         acc
 177       end
 178     end)
 179   end
 180 end