git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.PipelineFiltering do
   6   @callback pipeline_filter(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
   7 end
   8
   9 defmodule Pleroma.Web.ActivityPub.MRF do
  10   require Logger
  11
  12   @behaviour Pleroma.Web.ActivityPub.MRF.PipelineFiltering
  13
  14   @mrf_config_descriptions [
  15     %{
  16       group: :pleroma,
  17       key: :mrf,
  18       tab: :mrf,
  19       label: "MRF",
  20       type: :group,
  21       description: "General MRF settings",
  22       children: [
  23         %{
  24           key: :policies,
  25           type: [:module, {:list, :module}],
  26           description:
  27             "A list of MRF policies enabled. Module names are shortened (removed leading `Pleroma.Web.ActivityPub.MRF.` part), but on adding custom module you need to use full name.",
  28           suggestions: {:list_behaviour_implementations, Pleroma.Web.ActivityPub.MRF}
  29         },
  30         %{
  31           key: :transparency,
  32           label: "MRF transparency",
  33           type: :boolean,
  34           description:
  35             "Make the content of your Message Rewrite Facility settings public (via nodeinfo)"
  36         },
  37         %{
  38           key: :transparency_exclusions,
  39           label: "MRF transparency exclusions",
  40           type: {:list, :string},
  41           description:
  42             "Exclude specific instance names from MRF transparency. The use of the exclusions feature will be disclosed in nodeinfo as a boolean value.",
  43           suggestions: [
  44             "exclusion.com"
  45           ]
  46         }
  47       ]
  48     }
  49   ]
  50
  51   @default_description %{
  52     label: "",
  53     description: ""
  54   }
  55
  56   @required_description_keys [:key, :related_policy]
  57
  58   @callback filter(Map.t()) :: {:ok | :reject, Map.t()}
  59   @callback describe() :: {:ok | :error, Map.t()}
  60   @callback config_description() :: %{
  61               optional(:children) => [map()],
  62               key: atom(),
  63               related_policy: String.t(),
  64               label: String.t(),
  65               description: String.t()
  66             }
  67   @optional_callbacks config_description: 0
  68
  69   def filter(policies, %{} = message) do
  70     policies
  71     |> Enum.reduce({:ok, message}, fn
  72       policy, {:ok, message} -> policy.filter(message)
  73       _, error -> error
  74     end)
  75   end
  76
  77   def filter(%{} = object), do: get_policies() |> filter(object)
  78
  79   @impl true
  80   def pipeline_filter(%{} = message, meta) do
  81     object = meta[:object_data]
  82     ap_id = message["object"]
  83
  84     if object && ap_id do
  85       with {:ok, message} <- filter(Map.put(message, "object", object)) do
  86         meta = Keyword.put(meta, :object_data, message["object"])
  87         {:ok, Map.put(message, "object", ap_id), meta}
  88       else
  89         {err, message} -> {err, message, meta}
  90       end
  91     else
  92       {err, message} = filter(message)
  93
  94       {err, message, meta}
  95     end
  96   end
  97
  98   def get_policies do
  99     Pleroma.Config.get([:mrf, :policies], []) |> get_policies()
 100   end
 101
 102   defp get_policies(policy) when is_atom(policy), do: [policy]
 103   defp get_policies(policies) when is_list(policies), do: policies
 104   defp get_policies(_), do: []
 105
 106   @spec subdomains_regex([String.t()]) :: [Regex.t()]
 107   def subdomains_regex(domains) when is_list(domains) do
 108     for domain <- domains, do: ~r(^#{String.replace(domain, "*.", "(.*\\.)*")}$)i
 109   end
 110
 111   @spec subdomain_match?([Regex.t()], String.t()) :: boolean()
 112   def subdomain_match?(domains, host) do
 113     Enum.any?(domains, fn domain -> Regex.match?(domain, host) end)
 114   end
 115
 116   def describe(policies) do
 117     {:ok, policy_configs} =
 118       policies
 119       |> Enum.reduce({:ok, %{}}, fn
 120         policy, {:ok, data} ->
 121           {:ok, policy_data} = policy.describe()
 122           {:ok, Map.merge(data, policy_data)}
 123
 124         _, error ->
 125           error
 126       end)
 127
 128     mrf_policies =
 129       get_policies()
 130       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
 131
 132     exclusions = Pleroma.Config.get([:mrf, :transparency_exclusions])
 133
 134     base =
 135       %{
 136         mrf_policies: mrf_policies,
 137         exclusions: length(exclusions) > 0
 138       }
 139       |> Map.merge(policy_configs)
 140
 141     {:ok, base}
 142   end
 143
 144   def describe, do: get_policies() |> describe()
 145
 146   def config_descriptions do
 147     Pleroma.Web.ActivityPub.MRF
 148     |> Pleroma.Docs.Generator.list_behaviour_implementations()
 149     |> config_descriptions()
 150   end
 151
 152   def config_descriptions(policies) do
 153     Enum.reduce(policies, @mrf_config_descriptions, fn policy, acc ->
 154       if function_exported?(policy, :config_description, 0) do
 155         description =
 156           @default_description
 157           |> Map.merge(policy.config_description)
 158           |> Map.put(:group, :pleroma)
 159           |> Map.put(:tab, :mrf)
 160           |> Map.put(:type, :group)
 161
 162         if Enum.all?(@required_description_keys, &Map.has_key?(description, &1)) do
 163           [description | acc]
 164         else
 165           Logger.warn(
 166             "#{policy} config description doesn't have one or all required keys #{
 167               inspect(@required_description_keys)
 168             }"
 169           )
 170
 171           acc
 172         end
 173       else
 174         Logger.debug(
 175           "#{policy} is excluded from config descriptions, because does not implement `config_description/0` method."
 176         )
 177
 178         acc
 179       end
 180     end)
 181   end
 182 end