git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/steal_emoji_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.StealEmojiPolicy do
   6   require Logger
   7
   8   alias Pleroma.Config
   9
  10   @moduledoc "Detect new emojis by their shortcode and steals them"
  11   @behaviour Pleroma.Web.ActivityPub.MRF
  12
  13   defp remote_host?(host), do: host != Config.get([Pleroma.Web.Endpoint, :url, :host])
  14
  15   defp accept_host?(host), do: host in Config.get([:mrf_steal_emoji, :hosts], [])
  16
  17   defp steal_emoji({shortcode, url}) do
  18     url = Pleroma.Web.MediaProxy.url(url)
  19     {:ok, response} = Pleroma.HTTP.get(url)
  20     size_limit = Config.get([:mrf_steal_emoji, :size_limit], 50_000)
  21
  22     if byte_size(response.body) <= size_limit do
  23       emoji_dir_path =
  24         Config.get(
  25           [:mrf_steal_emoji, :path],
  26           Path.join(Config.get([:instance, :static_dir]), "emoji/stolen")
  27         )
  28
  29       extension =
  30         url
  31         |> URI.parse()
  32         |> Map.get(:path)
  33         |> Path.basename()
  34         |> Path.extname()
  35
  36       file_path = Path.join([emoji_dir_path, shortcode <> (extension || ".png")])
  37
  38       try do
  39         :ok = File.write(file_path, response.body)
  40
  41         shortcode
  42       rescue
  43         e ->
  44           Logger.warn("MRF.StealEmojiPolicy: Failed to write to #{file_path}: #{inspect(e)}")
  45           nil
  46       end
  47     else
  48       Logger.debug(
  49         "MRF.StealEmojiPolicy: :#{shortcode}: at #{url} (#{byte_size(response.body)} B) over size limit (#{
  50           size_limit
  51         } B)"
  52       )
  53
  54       nil
  55     end
  56   rescue
  57     e ->
  58       Logger.warn("MRF.StealEmojiPolicy: Failed to fetch #{url}: #{inspect(e)}")
  59       nil
  60   end
  61
  62   @impl true
  63   def filter(%{"object" => %{"emoji" => foreign_emojis, "actor" => actor}} = message) do
  64     host = URI.parse(actor).host
  65
  66     if remote_host?(host) and accept_host?(host) do
  67       installed_emoji = Pleroma.Emoji.get_all() |> Enum.map(fn {k, _} -> k end)
  68
  69       new_emojis =
  70         foreign_emojis
  71         |> Enum.filter(fn {shortcode, _url} -> shortcode not in installed_emoji end)
  72         |> Enum.filter(fn {shortcode, _url} ->
  73           reject_emoji? =
  74             Config.get([:mrf_steal_emoji, :rejected_shortcodes], [])
  75             |> Enum.find(false, fn regex -> String.match?(shortcode, regex) end)
  76
  77           !reject_emoji?
  78         end)
  79         |> Enum.map(&steal_emoji(&1))
  80         |> Enum.filter(& &1)
  81
  82       if !Enum.empty?(new_emojis) do
  83         Logger.info("Stole new emojis: #{inspect(new_emojis)}")
  84         Pleroma.Emoji.reload()
  85       end
  86     end
  87
  88     {:ok, message}
  89   end
  90
  91   def filter(message), do: {:ok, message}
  92
  93   @impl true
  94   def describe do
  95     {:ok, %{}}
  96   end
  97 end