git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   2   alias Pleroma.User
   3   @behaviour Pleroma.Web.ActivityPub.MRF
   4
   5   @mrf_policy Application.get_env(:pleroma, :mrf_simple)
   6
   7   @accept Keyword.get(@mrf_policy, :accept)
   8   defp check_accept(%{host: actor_host} = actor_info, object)
   9        when length(@accept) > 0 and not (actor_host in @accept) do
  10     {:reject, nil}
  11   end
  12
  13   defp check_accept(actor_info, object), do: {:ok, object}
  14
  15   @reject Keyword.get(@mrf_policy, :reject)
  16   defp check_reject(%{host: actor_host} = actor_info, object) when actor_host in @reject do
  17     {:reject, nil}
  18   end
  19
  20   defp check_reject(actor_info, object), do: {:ok, object}
  21
  22   @media_removal Keyword.get(@mrf_policy, :media_removal)
  23   defp check_media_removal(%{host: actor_host} = actor_info, %{"type" => "Create"} = object)
  24        when actor_host in @media_removal do
  25     child_object = Map.delete(object["object"], "attachment")
  26     object = Map.put(object, "object", child_object)
  27     {:ok, object}
  28   end
  29
  30   defp check_media_removal(actor_info, object), do: {:ok, object}
  31
  32   @media_nsfw Keyword.get(@mrf_policy, :media_nsfw)
  33   defp check_media_nsfw(
  34          %{host: actor_host} = actor_info,
  35          %{
  36            "type" => "Create",
  37            "object" => %{"attachment" => child_attachment} = child_object
  38          } = object
  39        )
  40        when actor_host in @media_nsfw and length(child_attachment) > 0 do
  41     tags = (child_object["tag"] || []) ++ ["nsfw"]
  42     child_object = Map.put(child_object, "tags", tags)
  43     child_object = Map.put(child_object, "sensitive", true)
  44     object = Map.put(object, "object", child_object)
  45     {:ok, object}
  46   end
  47
  48   defp check_media_nsfw(actor_info, object), do: {:ok, object}
  49
  50   @ftl_removal Keyword.get(@mrf_policy, :federated_timeline_removal)
  51   defp check_ftl_removal(%{host: actor_host} = actor_info, object)
  52        when actor_host in @ftl_removal do
  53     user = User.get_by_ap_id(object["actor"])
  54
  55     # flip to/cc relationship to make the post unlisted
  56     object =
  57       if "https://www.w3.org/ns/activitystreams#Public" in object["to"] and
  58            user.follower_address in object["cc"] do
  59         to =
  60           List.delete(object["to"], "https://www.w3.org/ns/activitystreams#Public") ++
  61             [user.follower_address]
  62
  63         cc =
  64           List.delete(object["cc"], user.follower_address) ++
  65             ["https://www.w3.org/ns/activitystreams#Public"]
  66
  67         object
  68         |> Map.put("to", to)
  69         |> Map.put("cc", cc)
  70       else
  71         object
  72       end
  73
  74     {:ok, object}
  75   end
  76
  77   defp check_ftl_removal(actor_info, object), do: {:ok, object}
  78
  79   @impl true
  80   def filter(object) do
  81     actor_info = URI.parse(object["actor"])
  82
  83     with {:ok, object} <- check_accept(actor_info, object),
  84          {:ok, object} <- check_reject(actor_info, object),
  85          {:ok, object} <- check_media_removal(actor_info, object),
  86          {:ok, object} <- check_media_nsfw(actor_info, object),
  87          {:ok, object} <- check_ftl_removal(actor_info, object) do
  88       {:ok, object}
  89     else
  90       _e -> {:reject, nil}
  91     end
  92   end
  93 end