git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   6   @moduledoc "Filter activities depending on their origin instance"
   7   @behaviour Pleroma.Web.ActivityPub.MRF
   8
   9   alias Pleroma.Config
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.MRF
  13
  14   require Pleroma.Constants
  15
  16   defp check_accept(%{host: actor_host} = _actor_info, object) do
  17     accepts =
  18       Config.get([:mrf_simple, :accept])
  19       |> MRF.subdomains_regex()
  20
  21     cond do
  22       accepts == [] -> {:ok, object}
  23       actor_host == Config.get([Pleroma.Web.Endpoint, :url, :host]) -> {:ok, object}
  24       MRF.subdomain_match?(accepts, actor_host) -> {:ok, object}
  25       true -> {:reject, "[SimplePolicy] host not in accept list"}
  26     end
  27   end
  28
  29   defp check_reject(%{host: actor_host} = _actor_info, object) do
  30     rejects =
  31       Config.get([:mrf_simple, :reject])
  32       |> MRF.subdomains_regex()
  33
  34     if MRF.subdomain_match?(rejects, actor_host) do
  35       {:reject, "[SimplePolicy] host in reject list"}
  36     else
  37       {:ok, object}
  38     end
  39   end
  40
  41   defp check_media_removal(
  42          %{host: actor_host} = _actor_info,
  43          %{"type" => "Create", "object" => %{"attachment" => child_attachment}} = object
  44        )
  45        when length(child_attachment) > 0 do
  46     media_removal =
  47       Config.get([:mrf_simple, :media_removal])
  48       |> MRF.subdomains_regex()
  49
  50     object =
  51       if MRF.subdomain_match?(media_removal, actor_host) do
  52         child_object = Map.delete(object["object"], "attachment")
  53         Map.put(object, "object", child_object)
  54       else
  55         object
  56       end
  57
  58     {:ok, object}
  59   end
  60
  61   defp check_media_removal(_actor_info, object), do: {:ok, object}
  62
  63   defp check_media_nsfw(
  64          %{host: actor_host} = _actor_info,
  65          %{
  66            "type" => "Create",
  67            "object" => child_object
  68          } = object
  69        )
  70        when is_map(child_object) do
  71     media_nsfw =
  72       Config.get([:mrf_simple, :media_nsfw])
  73       |> MRF.subdomains_regex()
  74
  75     object =
  76       if MRF.subdomain_match?(media_nsfw, actor_host) do
  77         tags = (child_object["tag"] || []) ++ ["nsfw"]
  78         child_object = Map.put(child_object, "tag", tags)
  79         child_object = Map.put(child_object, "sensitive", true)
  80         Map.put(object, "object", child_object)
  81       else
  82         object
  83       end
  84
  85     {:ok, object}
  86   end
  87
  88   defp check_media_nsfw(_actor_info, object), do: {:ok, object}
  89
  90   defp check_ftl_removal(%{host: actor_host} = _actor_info, object) do
  91     timeline_removal =
  92       Config.get([:mrf_simple, :federated_timeline_removal])
  93       |> MRF.subdomains_regex()
  94
  95     object =
  96       with true <- MRF.subdomain_match?(timeline_removal, actor_host),
  97            user <- User.get_cached_by_ap_id(object["actor"]),
  98            true <- Pleroma.Constants.as_public() in object["to"] do
  99         to = List.delete(object["to"], Pleroma.Constants.as_public()) ++ [user.follower_address]
 100
 101         cc = List.delete(object["cc"], user.follower_address) ++ [Pleroma.Constants.as_public()]
 102
 103         object
 104         |> Map.put("to", to)
 105         |> Map.put("cc", cc)
 106       else
 107         _ -> object
 108       end
 109
 110     {:ok, object}
 111   end
 112
 113   defp intersection(list1, list2) do
 114     list1 -- list1 -- list2
 115   end
 116
 117   defp check_followers_only(%{host: actor_host} = _actor_info, object) do
 118     followers_only =
 119       Config.get([:mrf_simple, :followers_only])
 120       |> MRF.subdomains_regex()
 121
 122     object =
 123       with true <- MRF.subdomain_match?(followers_only, actor_host),
 124            user <- User.get_cached_by_ap_id(object["actor"]) do
 125         # Don't use Map.get/3 intentionally, these must not be nil
 126         fixed_to = object["to"] || []
 127         fixed_cc = object["cc"] || []
 128
 129         to = FollowingRelationship.followers_ap_ids(user, fixed_to)
 130         cc = FollowingRelationship.followers_ap_ids(user, fixed_cc)
 131
 132         object
 133         |> Map.put("to", intersection([user.follower_address | to], fixed_to))
 134         |> Map.put("cc", intersection([user.follower_address | cc], fixed_cc))
 135       else
 136         _ -> object
 137       end
 138
 139     {:ok, object}
 140   end
 141
 142   defp check_report_removal(%{host: actor_host} = _actor_info, %{"type" => "Flag"} = object) do
 143     report_removal =
 144       Config.get([:mrf_simple, :report_removal])
 145       |> MRF.subdomains_regex()
 146
 147     if MRF.subdomain_match?(report_removal, actor_host) do
 148       {:reject, "[SimplePolicy] host in report_removal list"}
 149     else
 150       {:ok, object}
 151     end
 152   end
 153
 154   defp check_report_removal(_actor_info, object), do: {:ok, object}
 155
 156   defp check_avatar_removal(%{host: actor_host} = _actor_info, %{"icon" => _icon} = object) do
 157     avatar_removal =
 158       Config.get([:mrf_simple, :avatar_removal])
 159       |> MRF.subdomains_regex()
 160
 161     if MRF.subdomain_match?(avatar_removal, actor_host) do
 162       {:ok, Map.delete(object, "icon")}
 163     else
 164       {:ok, object}
 165     end
 166   end
 167
 168   defp check_avatar_removal(_actor_info, object), do: {:ok, object}
 169
 170   defp check_banner_removal(%{host: actor_host} = _actor_info, %{"image" => _image} = object) do
 171     banner_removal =
 172       Config.get([:mrf_simple, :banner_removal])
 173       |> MRF.subdomains_regex()
 174
 175     if MRF.subdomain_match?(banner_removal, actor_host) do
 176       {:ok, Map.delete(object, "image")}
 177     else
 178       {:ok, object}
 179     end
 180   end
 181
 182   defp check_banner_removal(_actor_info, object), do: {:ok, object}
 183
 184   defp check_object(%{"object" => object} = activity) do
 185     with {:ok, _object} <- filter(object) do
 186       {:ok, activity}
 187     end
 188   end
 189
 190   defp check_object(object), do: {:ok, object}
 191
 192   @impl true
 193   def filter(%{"type" => "Delete", "actor" => actor} = object) do
 194     %{host: actor_host} = URI.parse(actor)
 195
 196     reject_deletes =
 197       Config.get([:mrf_simple, :reject_deletes])
 198       |> MRF.subdomains_regex()
 199
 200     if MRF.subdomain_match?(reject_deletes, actor_host) do
 201       {:reject, "[SimplePolicy] host in reject_deletes list"}
 202     else
 203       {:ok, object}
 204     end
 205   end
 206
 207   @impl true
 208   def filter(%{"actor" => actor} = object) do
 209     actor_info = URI.parse(actor)
 210
 211     with {:ok, object} <- check_accept(actor_info, object),
 212          {:ok, object} <- check_reject(actor_info, object),
 213          {:ok, object} <- check_media_removal(actor_info, object),
 214          {:ok, object} <- check_media_nsfw(actor_info, object),
 215          {:ok, object} <- check_ftl_removal(actor_info, object),
 216          {:ok, object} <- check_followers_only(actor_info, object),
 217          {:ok, object} <- check_report_removal(actor_info, object),
 218          {:ok, object} <- check_object(object) do
 219       {:ok, object}
 220     else
 221       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 222       {:reject, _} = e -> e
 223       _ -> {:reject, "[SimplePolicy]"}
 224     end
 225   end
 226
 227   def filter(%{"id" => actor, "type" => obj_type} = object)
 228       when obj_type in ["Application", "Group", "Organization", "Person", "Service"] do
 229     actor_info = URI.parse(actor)
 230
 231     with {:ok, object} <- check_accept(actor_info, object),
 232          {:ok, object} <- check_reject(actor_info, object),
 233          {:ok, object} <- check_avatar_removal(actor_info, object),
 234          {:ok, object} <- check_banner_removal(actor_info, object) do
 235       {:ok, object}
 236     else
 237       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 238       {:reject, _} = e -> e
 239       _ -> {:reject, "[SimplePolicy]"}
 240     end
 241   end
 242
 243   def filter(object) when is_binary(object) do
 244     uri = URI.parse(object)
 245
 246     with {:ok, object} <- check_accept(uri, object),
 247          {:ok, object} <- check_reject(uri, object) do
 248       {:ok, object}
 249     else
 250       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 251       {:reject, _} = e -> e
 252       _ -> {:reject, "[SimplePolicy]"}
 253     end
 254   end
 255
 256   def filter(object), do: {:ok, object}
 257
 258   @impl true
 259   def describe do
 260     exclusions = Config.get([:mrf, :transparency_exclusions])
 261
 262     mrf_simple =
 263       Config.get(:mrf_simple)
 264       |> Enum.map(fn {k, v} -> {k, Enum.reject(v, fn v -> v in exclusions end)} end)
 265       |> Enum.into(%{})
 266
 267     {:ok, %{mrf_simple: mrf_simple}}
 268   end
 269
 270   @impl true
 271   def config_description do
 272     %{
 273       key: :mrf_simple,
 274       related_policy: "Pleroma.Web.ActivityPub.MRF.SimplePolicy",
 275       label: "MRF Simple",
 276       description: "Simple ingress policies",
 277       children: [
 278         %{
 279           key: :media_removal,
 280           type: {:list, :string},
 281           description: "List of instances to strip media attachments from",
 282           suggestions: ["example.com", "*.example.com"]
 283         },
 284         %{
 285           key: :media_nsfw,
 286           label: "Media NSFW",
 287           type: {:list, :string},
 288           description: "List of instances to tag all media as NSFW (sensitive) from",
 289           suggestions: ["example.com", "*.example.com"]
 290         },
 291         %{
 292           key: :federated_timeline_removal,
 293           type: {:list, :string},
 294           description:
 295             "List of instances to remove from the Federated (aka The Whole Known Network) Timeline",
 296           suggestions: ["example.com", "*.example.com"]
 297         },
 298         %{
 299           key: :reject,
 300           type: {:list, :string},
 301           description: "List of instances to reject activities from (except deletes)",
 302           suggestions: ["example.com", "*.example.com"]
 303         },
 304         %{
 305           key: :accept,
 306           type: {:list, :string},
 307           description: "List of instances to only accept activities from (except deletes)",
 308           suggestions: ["example.com", "*.example.com"]
 309         },
 310         %{
 311           key: :followers_only,
 312           type: {:list, :string},
 313           description: "Force posts from the given instances to be visible by followers only",
 314           suggestions: ["example.com", "*.example.com"]
 315         },
 316         %{
 317           key: :report_removal,
 318           type: {:list, :string},
 319           description: "List of instances to reject reports from",
 320           suggestions: ["example.com", "*.example.com"]
 321         },
 322         %{
 323           key: :avatar_removal,
 324           type: {:list, :string},
 325           description: "List of instances to strip avatars from",
 326           suggestions: ["example.com", "*.example.com"]
 327         },
 328         %{
 329           key: :banner_removal,
 330           type: {:list, :string},
 331           description: "List of instances to strip banners from",
 332           suggestions: ["example.com", "*.example.com"]
 333         },
 334         %{
 335           key: :reject_deletes,
 336           type: {:list, :string},
 337           description: "List of instances to reject deletions from",
 338           suggestions: ["example.com", "*.example.com"]
 339         }
 340       ]
 341     }
 342   end
 343 end