git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   2   alias Pleroma.User
   3   @behaviour Pleroma.Web.ActivityPub.MRF
   4
   5   @mrf_policy Application.get_env(:pleroma, :mrf_simple)
   6
   7   @accept Keyword.get(@mrf_policy, :accept)
   8   defp check_accept(actor_info, object) do
   9     if length(@accept) > 0 and not (actor_info.host in @accept) do
  10       {:reject, nil}
  11     else
  12       {:ok, object}
  13     end
  14   end
  15
  16   @reject Keyword.get(@mrf_policy, :reject)
  17   defp check_reject(actor_info, object) do
  18     if actor_info.host in @reject do
  19       {:reject, nil}
  20     else
  21       {:ok, object}
  22     end
  23   end
  24
  25   @media_removal Keyword.get(@mrf_policy, :media_removal)
  26   defp check_media_removal(actor_info, %{"type" => activity_type} = object)
  27        when activity_type == "Create" do
  28     if actor_info.host in @media_removal do
  29       child_object = Map.delete(object["object"], "attachment")
  30       object = Map.put(object, "object", child_object)
  31       {:ok, object}
  32     else
  33       {:ok, object}
  34     end
  35   end
  36
  37   defp check_media_removal(actor_info, object), do: {:ok, object}
  38
  39   @media_nsfw Keyword.get(@mrf_policy, :media_nsfw)
  40   defp check_media_nsfw(actor_info, %{"type" => activity_type} = object)
  41        when activity_type == "Create" do
  42     child_object = object["object"]
  43
  44     if actor_info.host in @media_nsfw and child_object["attachment"] != nil and
  45          length(child_object["attachment"]) > 0 do
  46       tags = (child_object["tag"] || []) ++ ["nsfw"]
  47       child_object = Map.put(child_object, "tags", tags)
  48       child_object = Map.put(child_object, "sensitive", true)
  49       object = Map.put(object, "object", child_object)
  50       {:ok, object}
  51     else
  52       {:ok, object}
  53     end
  54   end
  55
  56   defp check_media_nsfw(actor_info, object), do: {:ok, object}
  57
  58   @ftl_removal Keyword.get(@mrf_policy, :federated_timeline_removal)
  59   defp check_ftl_removal(actor_info, object) do
  60     if actor_info.host in @ftl_removal do
  61       user = User.get_by_ap_id(object["actor"])
  62
  63       # flip to/cc relationship to make the post unlisted
  64       object =
  65         if "https://www.w3.org/ns/activitystreams#Public" in object["to"] and
  66              user.follower_address in object["cc"] do
  67           to =
  68             List.delete(object["to"], "https://www.w3.org/ns/activitystreams#Public") ++
  69               [user.follower_address]
  70
  71           cc =
  72             List.delete(object["cc"], user.follower_address) ++
  73               ["https://www.w3.org/ns/activitystreams#Public"]
  74
  75           object
  76           |> Map.put("to", to)
  77           |> Map.put("cc", cc)
  78         else
  79           object
  80         end
  81
  82       {:ok, object}
  83     else
  84       {:ok, object}
  85     end
  86   end
  87
  88   @impl true
  89   def filter(object) do
  90     actor_info = URI.parse(object["actor"])
  91
  92     with {:ok, object} <- check_accept(actor_info, object),
  93          {:ok, object} <- check_reject(actor_info, object),
  94          {:ok, object} <- check_media_removal(actor_info, object),
  95          {:ok, object} <- check_media_nsfw(actor_info, object),
  96          {:ok, object} <- check_ftl_removal(actor_info, object) do
  97       {:ok, object}
  98     else
  99       _e -> {:reject, nil}
 100     end
 101   end
 102 end