git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   6   @moduledoc "Filter activities depending on their origin instance"
   7   @behaviour Pleroma.Web.ActivityPub.MRF
   8
   9   alias Pleroma.Config
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.MRF
  13
  14   require Pleroma.Constants
  15
  16   defp check_accept(%{host: actor_host} = _actor_info, object) do
  17     accepts =
  18       Config.get([:mrf_simple, :accept])
  19       |> MRF.subdomains_regex()
  20
  21     cond do
  22       accepts == [] -> {:ok, object}
  23       actor_host == Config.get([Pleroma.Web.Endpoint, :url, :host]) -> {:ok, object}
  24       MRF.subdomain_match?(accepts, actor_host) -> {:ok, object}
  25       true -> {:reject, "[SimplePolicy] host not in accept list"}
  26     end
  27   end
  28
  29   defp check_reject(%{host: actor_host} = _actor_info, object) do
  30     rejects =
  31       Config.get([:mrf_simple, :reject])
  32       |> MRF.subdomains_regex()
  33
  34     if MRF.subdomain_match?(rejects, actor_host) do
  35       {:reject, "[SimplePolicy] host in reject list"}
  36     else
  37       {:ok, object}
  38     end
  39   end
  40
  41   defp check_media_removal(
  42          %{host: actor_host} = _actor_info,
  43          %{"type" => "Create", "object" => %{"attachment" => child_attachment}} = object
  44        )
  45        when length(child_attachment) > 0 do
  46     media_removal =
  47       Config.get([:mrf_simple, :media_removal])
  48       |> MRF.subdomains_regex()
  49
  50     object =
  51       if MRF.subdomain_match?(media_removal, actor_host) do
  52         child_object = Map.delete(object["object"], "attachment")
  53         Map.put(object, "object", child_object)
  54       else
  55         object
  56       end
  57
  58     {:ok, object}
  59   end
  60
  61   defp check_media_removal(_actor_info, object), do: {:ok, object}
  62
  63   defp check_media_nsfw(
  64          %{host: actor_host} = _actor_info,
  65          %{
  66            "type" => "Create",
  67            "object" => %{} = _child_object
  68          } = object
  69        ) do
  70     media_nsfw =
  71       Config.get([:mrf_simple, :media_nsfw])
  72       |> MRF.subdomains_regex()
  73
  74     object =
  75       if MRF.subdomain_match?(media_nsfw, actor_host) do
  76         Kernel.put_in(object, ["object", "sensitive"], true)
  77       else
  78         object
  79       end
  80
  81     {:ok, object}
  82   end
  83
  84   defp check_media_nsfw(_actor_info, object), do: {:ok, object}
  85
  86   defp check_ftl_removal(%{host: actor_host} = _actor_info, object) do
  87     timeline_removal =
  88       Config.get([:mrf_simple, :federated_timeline_removal])
  89       |> MRF.subdomains_regex()
  90
  91     object =
  92       with true <- MRF.subdomain_match?(timeline_removal, actor_host),
  93            user <- User.get_cached_by_ap_id(object["actor"]),
  94            true <- Pleroma.Constants.as_public() in object["to"] do
  95         to = List.delete(object["to"], Pleroma.Constants.as_public()) ++ [user.follower_address]
  96
  97         cc = List.delete(object["cc"], user.follower_address) ++ [Pleroma.Constants.as_public()]
  98
  99         object
 100         |> Map.put("to", to)
 101         |> Map.put("cc", cc)
 102       else
 103         _ -> object
 104       end
 105
 106     {:ok, object}
 107   end
 108
 109   defp intersection(list1, list2) do
 110     list1 -- list1 -- list2
 111   end
 112
 113   defp check_followers_only(%{host: actor_host} = _actor_info, object) do
 114     followers_only =
 115       Config.get([:mrf_simple, :followers_only])
 116       |> MRF.subdomains_regex()
 117
 118     object =
 119       with true <- MRF.subdomain_match?(followers_only, actor_host),
 120            user <- User.get_cached_by_ap_id(object["actor"]) do
 121         # Don't use Map.get/3 intentionally, these must not be nil
 122         fixed_to = object["to"] || []
 123         fixed_cc = object["cc"] || []
 124
 125         to = FollowingRelationship.followers_ap_ids(user, fixed_to)
 126         cc = FollowingRelationship.followers_ap_ids(user, fixed_cc)
 127
 128         object
 129         |> Map.put("to", intersection([user.follower_address | to], fixed_to))
 130         |> Map.put("cc", intersection([user.follower_address | cc], fixed_cc))
 131       else
 132         _ -> object
 133       end
 134
 135     {:ok, object}
 136   end
 137
 138   defp check_report_removal(%{host: actor_host} = _actor_info, %{"type" => "Flag"} = object) do
 139     report_removal =
 140       Config.get([:mrf_simple, :report_removal])
 141       |> MRF.subdomains_regex()
 142
 143     if MRF.subdomain_match?(report_removal, actor_host) do
 144       {:reject, "[SimplePolicy] host in report_removal list"}
 145     else
 146       {:ok, object}
 147     end
 148   end
 149
 150   defp check_report_removal(_actor_info, object), do: {:ok, object}
 151
 152   defp check_avatar_removal(%{host: actor_host} = _actor_info, %{"icon" => _icon} = object) do
 153     avatar_removal =
 154       Config.get([:mrf_simple, :avatar_removal])
 155       |> MRF.subdomains_regex()
 156
 157     if MRF.subdomain_match?(avatar_removal, actor_host) do
 158       {:ok, Map.delete(object, "icon")}
 159     else
 160       {:ok, object}
 161     end
 162   end
 163
 164   defp check_avatar_removal(_actor_info, object), do: {:ok, object}
 165
 166   defp check_banner_removal(%{host: actor_host} = _actor_info, %{"image" => _image} = object) do
 167     banner_removal =
 168       Config.get([:mrf_simple, :banner_removal])
 169       |> MRF.subdomains_regex()
 170
 171     if MRF.subdomain_match?(banner_removal, actor_host) do
 172       {:ok, Map.delete(object, "image")}
 173     else
 174       {:ok, object}
 175     end
 176   end
 177
 178   defp check_banner_removal(_actor_info, object), do: {:ok, object}
 179
 180   defp check_object(%{"object" => object} = activity) do
 181     with {:ok, _object} <- filter(object) do
 182       {:ok, activity}
 183     end
 184   end
 185
 186   defp check_object(object), do: {:ok, object}
 187
 188   @impl true
 189   def filter(%{"type" => "Delete", "actor" => actor} = object) do
 190     %{host: actor_host} = URI.parse(actor)
 191
 192     reject_deletes =
 193       Config.get([:mrf_simple, :reject_deletes])
 194       |> MRF.subdomains_regex()
 195
 196     if MRF.subdomain_match?(reject_deletes, actor_host) do
 197       {:reject, "[SimplePolicy] host in reject_deletes list"}
 198     else
 199       {:ok, object}
 200     end
 201   end
 202
 203   @impl true
 204   def filter(%{"actor" => actor} = object) do
 205     actor_info = URI.parse(actor)
 206
 207     with {:ok, object} <- check_accept(actor_info, object),
 208          {:ok, object} <- check_reject(actor_info, object),
 209          {:ok, object} <- check_media_removal(actor_info, object),
 210          {:ok, object} <- check_media_nsfw(actor_info, object),
 211          {:ok, object} <- check_ftl_removal(actor_info, object),
 212          {:ok, object} <- check_followers_only(actor_info, object),
 213          {:ok, object} <- check_report_removal(actor_info, object),
 214          {:ok, object} <- check_object(object) do
 215       {:ok, object}
 216     else
 217       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 218       {:reject, _} = e -> e
 219       _ -> {:reject, "[SimplePolicy]"}
 220     end
 221   end
 222
 223   def filter(%{"id" => actor, "type" => obj_type} = object)
 224       when obj_type in ["Application", "Group", "Organization", "Person", "Service"] do
 225     actor_info = URI.parse(actor)
 226
 227     with {:ok, object} <- check_accept(actor_info, object),
 228          {:ok, object} <- check_reject(actor_info, object),
 229          {:ok, object} <- check_avatar_removal(actor_info, object),
 230          {:ok, object} <- check_banner_removal(actor_info, object) do
 231       {:ok, object}
 232     else
 233       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 234       {:reject, _} = e -> e
 235       _ -> {:reject, "[SimplePolicy]"}
 236     end
 237   end
 238
 239   def filter(object) when is_binary(object) do
 240     uri = URI.parse(object)
 241
 242     with {:ok, object} <- check_accept(uri, object),
 243          {:ok, object} <- check_reject(uri, object) do
 244       {:ok, object}
 245     else
 246       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 247       {:reject, _} = e -> e
 248       _ -> {:reject, "[SimplePolicy]"}
 249     end
 250   end
 251
 252   def filter(object), do: {:ok, object}
 253
 254   @impl true
 255   def describe do
 256     exclusions = Config.get([:mrf, :transparency_exclusions])
 257
 258     mrf_simple =
 259       Config.get(:mrf_simple)
 260       |> Enum.map(fn {k, v} -> {k, Enum.reject(v, fn v -> v in exclusions end)} end)
 261       |> Enum.into(%{})
 262
 263     {:ok, %{mrf_simple: mrf_simple}}
 264   end
 265
 266   @impl true
 267   def config_description do
 268     %{
 269       key: :mrf_simple,
 270       related_policy: "Pleroma.Web.ActivityPub.MRF.SimplePolicy",
 271       label: "MRF Simple",
 272       description: "Simple ingress policies",
 273       children: [
 274         %{
 275           key: :media_removal,
 276           type: {:list, :string},
 277           description: "List of instances to strip media attachments from",
 278           suggestions: ["example.com", "*.example.com"]
 279         },
 280         %{
 281           key: :media_nsfw,
 282           label: "Media NSFW",
 283           type: {:list, :string},
 284           description: "List of instances to tag all media as NSFW (sensitive) from",
 285           suggestions: ["example.com", "*.example.com"]
 286         },
 287         %{
 288           key: :federated_timeline_removal,
 289           type: {:list, :string},
 290           description:
 291             "List of instances to remove from the Federated (aka The Whole Known Network) Timeline",
 292           suggestions: ["example.com", "*.example.com"]
 293         },
 294         %{
 295           key: :reject,
 296           type: {:list, :string},
 297           description: "List of instances to reject activities from (except deletes)",
 298           suggestions: ["example.com", "*.example.com"]
 299         },
 300         %{
 301           key: :accept,
 302           type: {:list, :string},
 303           description: "List of instances to only accept activities from (except deletes)",
 304           suggestions: ["example.com", "*.example.com"]
 305         },
 306         %{
 307           key: :followers_only,
 308           type: {:list, :string},
 309           description: "Force posts from the given instances to be visible by followers only",
 310           suggestions: ["example.com", "*.example.com"]
 311         },
 312         %{
 313           key: :report_removal,
 314           type: {:list, :string},
 315           description: "List of instances to reject reports from",
 316           suggestions: ["example.com", "*.example.com"]
 317         },
 318         %{
 319           key: :avatar_removal,
 320           type: {:list, :string},
 321           description: "List of instances to strip avatars from",
 322           suggestions: ["example.com", "*.example.com"]
 323         },
 324         %{
 325           key: :banner_removal,
 326           type: {:list, :string},
 327           description: "List of instances to strip banners from",
 328           suggestions: ["example.com", "*.example.com"]
 329         },
 330         %{
 331           key: :reject_deletes,
 332           type: {:list, :string},
 333           description: "List of instances to reject deletions from",
 334           suggestions: ["example.com", "*.example.com"]
 335         }
 336       ]
 337     }
 338   end
 339 end