git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   2   alias Pleroma.User
   3   @behaviour Pleroma.Web.ActivityPub.MRF
   4
   5   @mrf_policy Application.get_env(:pleroma, :mrf_simple)
   6
   7   @accept Keyword.get(@mrf_policy, :accept)
   8   defp check_accept(actor_info, object) do
   9     if length(@accept) > 0 and not actor_info.host in @accept do
  10       {:reject, nil}
  11     else
  12       {:ok, object}
  13     end
  14   end
  15
  16   @reject Keyword.get(@mrf_policy, :reject)
  17   defp check_reject(actor_info, object) do
  18     if actor_info.host in @reject do
  19       {:reject, nil}
  20     else
  21       {:ok, object}
  22     end
  23   end
  24
  25   @media_removal Keyword.get(@mrf_policy, :media_removal)
  26   defp check_media_removal(actor_info, object) do
  27     if actor_info.host in @media_removal do
  28       child_object = Map.delete(object["object"], "attachment")
  29       object = Map.put(object, "object", child_object)
  30       {:ok, object}
  31     else
  32       {:ok, object}
  33     end
  34   end
  35
  36   @media_nsfw Keyword.get(@mrf_policy, :media_nsfw)
  37   defp check_media_nsfw(actor_info, object) do
  38     child_object = object["object"]
  39
  40     if actor_info.host in @media_nsfw and child_object["attachment"] != nil and
  41          length(child_object["attachment"]) > 0 do
  42       tags = (child_object["tag"] || []) ++ ["nsfw"]
  43       child_object = Map.put(child_object, "tags", tags)
  44       child_object = Map.put(child_object, "sensitive", true)
  45       object = Map.put(object, "object", child_object)
  46       {:ok, object}
  47     else
  48       {:ok, object}
  49     end
  50   end
  51
  52   @ftl_removal Keyword.get(@mrf_policy, :federated_timeline_removal)
  53   defp check_ftl_removal(actor_info, object) do
  54     if actor_info.host in @ftl_removal do
  55       user = User.get_by_ap_id(object["actor"])
  56
  57       # flip to/cc relationship to make the post unlisted
  58       object =
  59         if "https://www.w3.org/ns/activitystreams#Public" in object["to"] and
  60              user.follower_address in object["cc"] do
  61           to =
  62             List.delete(object["to"], "https://www.w3.org/ns/activitystreams#Public") ++
  63               [user.follower_address]
  64
  65           cc =
  66             List.delete(object["cc"], user.follower_address) ++
  67               ["https://www.w3.org/ns/activitystreams#Public"]
  68
  69           object
  70           |> Map.put("to", to)
  71           |> Map.put("cc", cc)
  72         else
  73           object
  74         end
  75
  76       {:ok, object}
  77     else
  78       {:ok, object}
  79     end
  80   end
  81
  82   @impl true
  83   def filter(object) do
  84     actor_info = URI.parse(object["actor"])
  85
  86     with {:ok, object} <- check_accept(actor_info, object),
  87          {:ok, object} <- check_reject(actor_info, object),
  88          {:ok, object} <- check_media_removal(actor_info, object),
  89          {:ok, object} <- check_media_nsfw(actor_info, object),
  90          {:ok, object} <- check_ftl_removal(actor_info, object) do
  91       {:ok, object}
  92     else
  93       _e -> {:reject, nil}
  94     end
  95   end
  96 end