git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   6   @moduledoc "Filter activities depending on their origin instance"
   7   @behaviour Pleroma.Web.ActivityPub.MRF
   8
   9   alias Pleroma.Config
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.MRF
  13
  14   require Pleroma.Constants
  15
  16   defp check_accept(%{host: actor_host} = _actor_info, object) do
  17     accepts =
  18       Config.get([:mrf_simple, :accept])
  19       |> MRF.subdomains_regex()
  20
  21     cond do
  22       accepts == [] -> {:ok, object}
  23       actor_host == Config.get([Pleroma.Web.Endpoint, :url, :host]) -> {:ok, object}
  24       MRF.subdomain_match?(accepts, actor_host) -> {:ok, object}
  25       true -> {:reject, "[SimplePolicy] host not in accept list"}
  26     end
  27   end
  28
  29   defp check_reject(%{host: actor_host} = _actor_info, object) do
  30     rejects =
  31       Config.get([:mrf_simple, :reject])
  32       |> MRF.subdomains_regex()
  33
  34     if MRF.subdomain_match?(rejects, actor_host) do
  35       {:reject, "[SimplePolicy] host in reject list"}
  36     else
  37       {:ok, object}
  38     end
  39   end
  40
  41   defp check_media_removal(
  42          %{host: actor_host} = _actor_info,
  43          %{"type" => "Create", "object" => %{"attachment" => child_attachment}} = object
  44        )
  45        when length(child_attachment) > 0 do
  46     media_removal =
  47       Config.get([:mrf_simple, :media_removal])
  48       |> MRF.subdomains_regex()
  49
  50     object =
  51       if MRF.subdomain_match?(media_removal, actor_host) do
  52         child_object = Map.delete(object["object"], "attachment")
  53         Map.put(object, "object", child_object)
  54       else
  55         object
  56       end
  57
  58     {:ok, object}
  59   end
  60
  61   defp check_media_removal(_actor_info, object), do: {:ok, object}
  62
  63   defp check_media_nsfw(
  64          %{host: actor_host} = _actor_info,
  65          %{
  66            "type" => "Create",
  67            "object" => child_object
  68          } = object
  69        ) do
  70     media_nsfw =
  71       Config.get([:mrf_simple, :media_nsfw])
  72       |> MRF.subdomains_regex()
  73
  74     object =
  75       if MRF.subdomain_match?(media_nsfw, actor_host) do
  76         tags = (child_object["tag"] || []) ++ ["nsfw"]
  77         child_object = Map.put(child_object, "tag", tags)
  78         child_object = Map.put(child_object, "sensitive", true)
  79         Map.put(object, "object", child_object)
  80       else
  81         object
  82       end
  83
  84     {:ok, object}
  85   end
  86
  87   defp check_media_nsfw(_actor_info, object), do: {:ok, object}
  88
  89   defp check_ftl_removal(%{host: actor_host} = _actor_info, object) do
  90     timeline_removal =
  91       Config.get([:mrf_simple, :federated_timeline_removal])
  92       |> MRF.subdomains_regex()
  93
  94     object =
  95       with true <- MRF.subdomain_match?(timeline_removal, actor_host),
  96            user <- User.get_cached_by_ap_id(object["actor"]),
  97            true <- Pleroma.Constants.as_public() in object["to"] do
  98         to = List.delete(object["to"], Pleroma.Constants.as_public()) ++ [user.follower_address]
  99
 100         cc = List.delete(object["cc"], user.follower_address) ++ [Pleroma.Constants.as_public()]
 101
 102         object
 103         |> Map.put("to", to)
 104         |> Map.put("cc", cc)
 105       else
 106         _ -> object
 107       end
 108
 109     {:ok, object}
 110   end
 111
 112   defp check_silence(%{host: actor_host} = _actor_info, object) do
 113     silence =
 114       Config.get([:mrf_simple, :silence])
 115       |> MRF.subdomains_regex()
 116
 117     object =
 118       with true <- MRF.subdomain_match?(silence, actor_host),
 119            user <- User.get_cached_by_ap_id(object["actor"]) do
 120         # Don't use Map.get/3 intentionally, these must not be nil
 121         fixed_to = object["to"] || []
 122         fixed_cc = object["cc"] || []
 123
 124         to = FollowingRelationship.followers_ap_ids(user, fixed_to)
 125         cc = FollowingRelationship.followers_ap_ids(user, fixed_cc)
 126
 127         object
 128         |> Map.put("to", [user.follower_address] ++ to)
 129         |> Map.put("cc", cc)
 130       else
 131         _ -> object
 132       end
 133
 134     {:ok, object}
 135   end
 136
 137   defp check_report_removal(%{host: actor_host} = _actor_info, %{"type" => "Flag"} = object) do
 138     report_removal =
 139       Config.get([:mrf_simple, :report_removal])
 140       |> MRF.subdomains_regex()
 141
 142     if MRF.subdomain_match?(report_removal, actor_host) do
 143       {:reject, "[SimplePolicy] host in report_removal list"}
 144     else
 145       {:ok, object}
 146     end
 147   end
 148
 149   defp check_report_removal(_actor_info, object), do: {:ok, object}
 150
 151   defp check_avatar_removal(%{host: actor_host} = _actor_info, %{"icon" => _icon} = object) do
 152     avatar_removal =
 153       Config.get([:mrf_simple, :avatar_removal])
 154       |> MRF.subdomains_regex()
 155
 156     if MRF.subdomain_match?(avatar_removal, actor_host) do
 157       {:ok, Map.delete(object, "icon")}
 158     else
 159       {:ok, object}
 160     end
 161   end
 162
 163   defp check_avatar_removal(_actor_info, object), do: {:ok, object}
 164
 165   defp check_banner_removal(%{host: actor_host} = _actor_info, %{"image" => _image} = object) do
 166     banner_removal =
 167       Config.get([:mrf_simple, :banner_removal])
 168       |> MRF.subdomains_regex()
 169
 170     if MRF.subdomain_match?(banner_removal, actor_host) do
 171       {:ok, Map.delete(object, "image")}
 172     else
 173       {:ok, object}
 174     end
 175   end
 176
 177   defp check_banner_removal(_actor_info, object), do: {:ok, object}
 178
 179   @impl true
 180   def filter(%{"type" => "Delete", "actor" => actor} = object) do
 181     %{host: actor_host} = URI.parse(actor)
 182
 183     reject_deletes =
 184       Config.get([:mrf_simple, :reject_deletes])
 185       |> MRF.subdomains_regex()
 186
 187     if MRF.subdomain_match?(reject_deletes, actor_host) do
 188       {:reject, "[SimplePolicy] host in reject_deletes list"}
 189     else
 190       {:ok, object}
 191     end
 192   end
 193
 194   @impl true
 195   def filter(%{"actor" => actor} = object) do
 196     actor_info = URI.parse(actor)
 197
 198     with {:ok, object} <- check_accept(actor_info, object),
 199          {:ok, object} <- check_reject(actor_info, object),
 200          {:ok, object} <- check_media_removal(actor_info, object),
 201          {:ok, object} <- check_media_nsfw(actor_info, object),
 202          {:ok, object} <- check_ftl_removal(actor_info, object),
 203          {:ok, object} <- check_silence(actor_info, object),
 204          {:ok, object} <- check_report_removal(actor_info, object) do
 205       {:ok, object}
 206     else
 207       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 208       {:reject, _} = e -> e
 209       _ -> {:reject, "[SimplePolicy]"}
 210     end
 211   end
 212
 213   def filter(%{"id" => actor, "type" => obj_type} = object)
 214       when obj_type in ["Application", "Group", "Organization", "Person", "Service"] do
 215     actor_info = URI.parse(actor)
 216
 217     with {:ok, object} <- check_accept(actor_info, object),
 218          {:ok, object} <- check_reject(actor_info, object),
 219          {:ok, object} <- check_avatar_removal(actor_info, object),
 220          {:ok, object} <- check_banner_removal(actor_info, object) do
 221       {:ok, object}
 222     else
 223       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 224       {:reject, _} = e -> e
 225       _ -> {:reject, "[SimplePolicy]"}
 226     end
 227   end
 228
 229   def filter(object), do: {:ok, object}
 230
 231   @impl true
 232   def describe do
 233     exclusions = Config.get([:mrf, :transparency_exclusions])
 234
 235     mrf_simple =
 236       Config.get(:mrf_simple)
 237       |> Enum.map(fn {k, v} -> {k, Enum.reject(v, fn v -> v in exclusions end)} end)
 238       |> Enum.into(%{})
 239
 240     {:ok, %{mrf_simple: mrf_simple}}
 241   end
 242 end