git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   6   alias Pleroma.User
   7   @moduledoc "Filter activities depending on their origin instance"
   8   @behaviour Pleroma.Web.ActivityPub.MRF
   9
  10   defp check_accept(%{host: actor_host} = _actor_info, object) do
  11     accepts = Pleroma.Config.get([:mrf_simple, :accept])
  12
  13     cond do
  14       accepts == [] -> {:ok, object}
  15       actor_host == Pleroma.Config.get([Pleroma.Web.Endpoint, :url, :host]) -> {:ok, object}
  16       Enum.member?(accepts, actor_host) -> {:ok, object}
  17       true -> {:reject, nil}
  18     end
  19   end
  20
  21   defp check_reject(%{host: actor_host} = _actor_info, object) do
  22     if Enum.member?(Pleroma.Config.get([:mrf_simple, :reject]), actor_host) do
  23       {:reject, nil}
  24     else
  25       {:ok, object}
  26     end
  27   end
  28
  29   defp check_media_removal(
  30          %{host: actor_host} = _actor_info,
  31          %{"type" => "Create", "object" => %{"attachment" => child_attachment}} = object
  32        )
  33        when length(child_attachment) > 0 do
  34     object =
  35       if Enum.member?(Pleroma.Config.get([:mrf_simple, :media_removal]), actor_host) do
  36         child_object = Map.delete(object["object"], "attachment")
  37         Map.put(object, "object", child_object)
  38       else
  39         object
  40       end
  41
  42     {:ok, object}
  43   end
  44
  45   defp check_media_removal(_actor_info, object), do: {:ok, object}
  46
  47   defp check_media_nsfw(
  48          %{host: actor_host} = _actor_info,
  49          %{
  50            "type" => "Create",
  51            "object" => child_object
  52          } = object
  53        ) do
  54     object =
  55       if Enum.member?(Pleroma.Config.get([:mrf_simple, :media_nsfw]), actor_host) do
  56         tags = (child_object["tag"] || []) ++ ["nsfw"]
  57         child_object = Map.put(child_object, "tag", tags)
  58         child_object = Map.put(child_object, "sensitive", true)
  59         Map.put(object, "object", child_object)
  60       else
  61         object
  62       end
  63
  64     {:ok, object}
  65   end
  66
  67   defp check_media_nsfw(_actor_info, object), do: {:ok, object}
  68
  69   defp check_ftl_removal(%{host: actor_host} = _actor_info, object) do
  70     object =
  71       with true <-
  72              Enum.member?(
  73                Pleroma.Config.get([:mrf_simple, :federated_timeline_removal]),
  74                actor_host
  75              ),
  76            user <- User.get_cached_by_ap_id(object["actor"]),
  77            true <- "https://www.w3.org/ns/activitystreams#Public" in object["to"],
  78            true <- user.follower_address in object["cc"] do
  79         to =
  80           List.delete(object["to"], "https://www.w3.org/ns/activitystreams#Public") ++
  81             [user.follower_address]
  82
  83         cc =
  84           List.delete(object["cc"], user.follower_address) ++
  85             ["https://www.w3.org/ns/activitystreams#Public"]
  86
  87         object
  88         |> Map.put("to", to)
  89         |> Map.put("cc", cc)
  90       else
  91         _ -> object
  92       end
  93
  94     {:ok, object}
  95   end
  96
  97   defp check_report_removal(%{host: actor_host} = _actor_info, %{"type" => "Flag"} = object) do
  98     if actor_host in Pleroma.Config.get([:mrf_simple, :report_removal]) do
  99       {:reject, nil}
 100     else
 101       {:ok, object}
 102     end
 103   end
 104
 105   defp check_report_removal(_actor_info, object), do: {:ok, object}
 106
 107   defp check_avatar_removal(%{host: actor_host} = _actor_info, %{"icon" => _icon} = object) do
 108     if actor_host in Pleroma.Config.get([:mrf_simple, :avatar_removal]) do
 109       {:ok, Map.delete(object, "icon")}
 110     else
 111       {:ok, object}
 112     end
 113   end
 114
 115   defp check_avatar_removal(_actor_info, object), do: {:ok, object}
 116
 117   defp check_banner_removal(%{host: actor_host} = _actor_info, %{"image" => _image} = object) do
 118     if actor_host in Pleroma.Config.get([:mrf_simple, :banner_removal]) do
 119       {:ok, Map.delete(object, "image")}
 120     else
 121       {:ok, object}
 122     end
 123   end
 124
 125   defp check_banner_removal(_actor_info, object), do: {:ok, object}
 126
 127   @impl true
 128   def filter(%{"actor" => actor} = object) do
 129     actor_info = URI.parse(actor)
 130
 131     with {:ok, object} <- check_accept(actor_info, object),
 132          {:ok, object} <- check_reject(actor_info, object),
 133          {:ok, object} <- check_media_removal(actor_info, object),
 134          {:ok, object} <- check_media_nsfw(actor_info, object),
 135          {:ok, object} <- check_ftl_removal(actor_info, object),
 136          {:ok, object} <- check_report_removal(actor_info, object) do
 137       {:ok, object}
 138     else
 139       _e -> {:reject, nil}
 140     end
 141   end
 142
 143   def filter(%{"id" => actor, "type" => obj_type} = object)
 144       when obj_type in ["Application", "Group", "Organization", "Person", "Service"] do
 145     actor_info = URI.parse(actor)
 146
 147     with {:ok, object} <- check_avatar_removal(actor_info, object),
 148          {:ok, object} <- check_banner_removal(actor_info, object) do
 149       {:ok, object}
 150     else
 151       _e -> {:reject, nil}
 152     end
 153   end
 154
 155   def filter(object), do: {:ok, object}
 156 end