git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   6   alias Pleroma.User
   7   @behaviour Pleroma.Web.ActivityPub.MRF
   8
   9   defp check_accept(%{host: actor_host} = _actor_info, object) do
  10     accepts = Pleroma.Config.get([:mrf_simple, :accept])
  11
  12     cond do
  13       accepts == [] -> {:ok, object}
  14       actor_host == Pleroma.Config.get([Pleroma.Web.Endpoint, :url, :host]) -> {:ok, object}
  15       Enum.member?(accepts, actor_host) -> {:ok, object}
  16       true -> {:reject, nil}
  17     end
  18   end
  19
  20   defp check_reject(%{host: actor_host} = _actor_info, object) do
  21     if Enum.member?(Pleroma.Config.get([:mrf_simple, :reject]), actor_host) do
  22       {:reject, nil}
  23     else
  24       {:ok, object}
  25     end
  26   end
  27
  28   defp check_media_removal(
  29          %{host: actor_host} = _actor_info,
  30          %{"type" => "Create", "object" => %{"attachment" => child_attachment}} = object
  31        )
  32        when length(child_attachment) > 0 do
  33     object =
  34       if Enum.member?(Pleroma.Config.get([:mrf_simple, :media_removal]), actor_host) do
  35         child_object = Map.delete(object["object"], "attachment")
  36         Map.put(object, "object", child_object)
  37       else
  38         object
  39       end
  40
  41     {:ok, object}
  42   end
  43
  44   defp check_media_removal(_actor_info, object), do: {:ok, object}
  45
  46   defp check_media_nsfw(
  47          %{host: actor_host} = _actor_info,
  48          %{
  49            "type" => "Create",
  50            "object" => %{"attachment" => child_attachment} = child_object
  51          } = object
  52        )
  53        when length(child_attachment) > 0 do
  54     object =
  55       if Enum.member?(Pleroma.Config.get([:mrf_simple, :media_nsfw]), actor_host) do
  56         tags = (child_object["tag"] || []) ++ ["nsfw"]
  57         child_object = Map.put(child_object, "tags", tags)
  58         child_object = Map.put(child_object, "sensitive", true)
  59         Map.put(object, "object", child_object)
  60       else
  61         object
  62       end
  63
  64     {:ok, object}
  65   end
  66
  67   defp check_media_nsfw(_actor_info, object), do: {:ok, object}
  68
  69   defp check_ftl_removal(%{host: actor_host} = _actor_info, object) do
  70     object =
  71       with true <-
  72              Enum.member?(
  73                Pleroma.Config.get([:mrf_simple, :federated_timeline_removal]),
  74                actor_host
  75              ),
  76            user <- User.get_cached_by_ap_id(object["actor"]),
  77            true <- "https://www.w3.org/ns/activitystreams#Public" in object["to"],
  78            true <- user.follower_address in object["cc"] do
  79         to =
  80           List.delete(object["to"], "https://www.w3.org/ns/activitystreams#Public") ++
  81             [user.follower_address]
  82
  83         cc =
  84           List.delete(object["cc"], user.follower_address) ++
  85             ["https://www.w3.org/ns/activitystreams#Public"]
  86
  87         object
  88         |> Map.put("to", to)
  89         |> Map.put("cc", cc)
  90       else
  91         _ -> object
  92       end
  93
  94     {:ok, object}
  95   end
  96
  97   @impl true
  98   def filter(object) do
  99     actor_info = URI.parse(object["actor"])
 100
 101     with {:ok, object} <- check_accept(actor_info, object),
 102          {:ok, object} <- check_reject(actor_info, object),
 103          {:ok, object} <- check_media_removal(actor_info, object),
 104          {:ok, object} <- check_media_nsfw(actor_info, object),
 105          {:ok, object} <- check_ftl_removal(actor_info, object) do
 106       {:ok, object}
 107     else
 108       _e -> {:reject, nil}
 109     end
 110   end
 111 end