git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/anti_followbot_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.AntiFollowbotPolicy do
   6   alias Pleroma.User
   7
   8   @moduledoc "Prevent followbots from following with a bit of heuristic"
   9
  10   @behaviour Pleroma.Web.ActivityPub.MRF
  11
  12   # XXX: this should become User.normalize_by_ap_id() or similar, really.
  13   defp normalize_by_ap_id(%{"id" => id}), do: User.get_cached_by_ap_id(id)
  14   defp normalize_by_ap_id(uri) when is_binary(uri), do: User.get_cached_by_ap_id(uri)
  15   defp normalize_by_ap_id(_), do: nil
  16
  17   defp score_nickname("followbot@" <> _), do: 1.0
  18   defp score_nickname("federationbot@" <> _), do: 1.0
  19   defp score_nickname("federation_bot@" <> _), do: 1.0
  20   defp score_nickname(_), do: 0.0
  21
  22   defp score_displayname("federation bot"), do: 1.0
  23   defp score_displayname("federationbot"), do: 1.0
  24   defp score_displayname("fedibot"), do: 1.0
  25   defp score_displayname(_), do: 0.0
  26
  27   defp determine_if_followbot(%User{nickname: nickname, name: displayname}) do
  28     # nickname will always be a binary string because it's generated by Pleroma.
  29     nick_score =
  30       nickname
  31       |> String.downcase()
  32       |> score_nickname()
  33
  34     # displayname will either be a binary string or nil, if a displayname isn't set.
  35     name_score =
  36       if is_binary(displayname) do
  37         displayname
  38         |> String.downcase()
  39         |> score_displayname()
  40       else
  41         0.0
  42       end
  43
  44     nick_score + name_score
  45   end
  46
  47   defp determine_if_followbot(_), do: 0.0
  48
  49   @impl true
  50   def filter(%{"type" => "Follow", "actor" => actor_id} = message) do
  51     %User{} = actor = normalize_by_ap_id(actor_id)
  52
  53     score = determine_if_followbot(actor)
  54
  55     # TODO: scan biography data for keywords and score it somehow.
  56     if score < 0.8 do
  57       {:ok, message}
  58     else
  59       {:reject, nil}
  60     end
  61   end
  62
  63   @impl true
  64   def filter(message), do: {:ok, message}
  65
  66   @impl true
  67   def describe, do: {:ok, %{}}
  68 end