git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/anti_followbot_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.AntiFollowbotPolicy do
   6   alias Pleroma.User
   7
   8   @behaviour Pleroma.Web.ActivityPub.MRF
   9
  10   # XXX: this should become User.normalize_by_ap_id() or similar, really.
  11   defp normalize_by_ap_id(%{"id" => id}), do: User.get_cached_by_ap_id(id)
  12   defp normalize_by_ap_id(uri) when is_binary(uri), do: User.get_cached_by_ap_id(uri)
  13   defp normalize_by_ap_id(_), do: nil
  14
  15   defp score_nickname("followbot@" <> _), do: 1.0
  16   defp score_nickname("federationbot@" <> _), do: 1.0
  17   defp score_nickname("federation_bot@" <> _), do: 1.0
  18   defp score_nickname(_), do: 0.0
  19
  20   defp score_displayname("federation bot"), do: 1.0
  21   defp score_displayname("federationbot"), do: 1.0
  22   defp score_displayname("fedibot"), do: 1.0
  23   defp score_displayname(_), do: 0.0
  24
  25   defp determine_if_followbot(%User{nickname: nickname, name: displayname}) do
  26     nick_score =
  27       nickname
  28       |> String.downcase()
  29       |> score_nickname()
  30
  31     name_score =
  32       displayname
  33       |> String.downcase()
  34       |> score_displayname()
  35
  36     nick_score + name_score
  37   end
  38
  39   defp determine_if_followbot(_), do: 0.0
  40
  41   @impl true
  42   def filter(%{"type" => "Follow", "actor" => actor_id} = message) do
  43     %User{} = actor = normalize_by_ap_id(actor_id)
  44
  45     score = determine_if_followbot(actor)
  46
  47     # TODO: scan biography data for keywords and score it somehow.
  48     if score < 0.8 do
  49       {:ok, message}
  50     else
  51       {:reject, nil}
  52     end
  53   end
  54
  55   @impl true
  56   def filter(message), do: {:ok, message}
  57 end