git.squeep.com Git - akkoma/blob - lib/pleroma/user_relationship.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.UserRelationship do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.UserRelationship
  14
  15   schema "user_relationships" do
  16     belongs_to(:source, User, type: FlakeId.Ecto.CompatType)
  17     belongs_to(:target, User, type: FlakeId.Ecto.CompatType)
  18     field(:relationship_type, UserRelationshipTypeEnum)
  19
  20     timestamps(updated_at: false)
  21   end
  22
  23   for relationship_type <- Keyword.keys(UserRelationshipTypeEnum.__enum_map__()) do
  24     # `def create_block/2`, `def create_mute/2`, `def create_reblog_mute/2`,
  25     #   `def create_notification_mute/2`, `def create_inverse_subscription/2`
  26     def unquote(:"create_#{relationship_type}")(source, target),
  27       do: create(unquote(relationship_type), source, target)
  28
  29     # `def delete_block/2`, `def delete_mute/2`, `def delete_reblog_mute/2`,
  30     #   `def delete_notification_mute/2`, `def delete_inverse_subscription/2`
  31     def unquote(:"delete_#{relationship_type}")(source, target),
  32       do: delete(unquote(relationship_type), source, target)
  33
  34     # `def block_exists?/2`, `def mute_exists?/2`, `def reblog_mute_exists?/2`,
  35     #   `def notification_mute_exists?/2`, `def inverse_subscription_exists?/2`
  36     def unquote(:"#{relationship_type}_exists?")(source, target),
  37       do: exists?(unquote(relationship_type), source, target)
  38   end
  39
  40   def changeset(%UserRelationship{} = user_relationship, params \\ %{}) do
  41     user_relationship
  42     |> cast(params, [:relationship_type, :source_id, :target_id])
  43     |> validate_required([:relationship_type, :source_id, :target_id])
  44     |> unique_constraint(:relationship_type,
  45       name: :user_relationships_source_id_relationship_type_target_id_index
  46     )
  47     |> validate_not_self_relationship()
  48   end
  49
  50   def exists?(relationship_type, %User{} = source, %User{} = target) do
  51     UserRelationship
  52     |> where(relationship_type: ^relationship_type, source_id: ^source.id, target_id: ^target.id)
  53     |> Repo.exists?()
  54   end
  55
  56   def create(relationship_type, %User{} = source, %User{} = target) do
  57     %UserRelationship{}
  58     |> changeset(%{
  59       relationship_type: relationship_type,
  60       source_id: source.id,
  61       target_id: target.id
  62     })
  63     |> Repo.insert(
  64       on_conflict: {:replace_all_except, [:id]},
  65       conflict_target: [:source_id, :relationship_type, :target_id]
  66     )
  67   end
  68
  69   def delete(relationship_type, %User{} = source, %User{} = target) do
  70     attrs = %{relationship_type: relationship_type, source_id: source.id, target_id: target.id}
  71
  72     case Repo.get_by(UserRelationship, attrs) do
  73       %UserRelationship{} = existing_record -> Repo.delete(existing_record)
  74       nil -> {:ok, nil}
  75     end
  76   end
  77
  78   defp validate_not_self_relationship(%Ecto.Changeset{} = changeset) do
  79     changeset
  80     |> validate_change(:target_id, fn _, target_id ->
  81       if target_id == get_field(changeset, :source_id) do
  82         [target_id: "can't be equal to source_id"]
  83       else
  84         []
  85       end
  86     end)
  87     |> validate_change(:source_id, fn _, source_id ->
  88       if source_id == get_field(changeset, :target_id) do
  89         [source_id: "can't be equal to target_id"]
  90       else
  91         []
  92       end
  93     end)
  94   end
  95 end