git.squeep.com Git - akkoma/blob - lib/pleroma/user_invite_token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.UserInviteToken do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9   import Ecto.Query
  10   alias Pleroma.Repo
  11   alias Pleroma.UserInviteToken
  12
  13   @type token :: String.t()
  14
  15   schema "user_invite_tokens" do
  16     field(:token, :string)
  17     field(:used, :boolean, default: false)
  18     field(:max_use, :integer)
  19     field(:expire_at, :date)
  20     field(:uses, :integer, default: 0)
  21     field(:invite_type, :string)
  22
  23     timestamps()
  24   end
  25
  26   @spec create_invite(map()) :: UserInviteToken.t()
  27   def create_invite(params \\ %{}) do
  28     %UserInviteToken{}
  29     |> cast(params, ~w(max_use expire_at)a)
  30     |> add_token()
  31     |> assign_type()
  32     |> Repo.insert()
  33   end
  34
  35   defp add_token(changeset) do
  36     token = :crypto.strong_rand_bytes(32) |> Base.url_encode64()
  37     put_change(changeset, :token, token)
  38   end
  39
  40   defp assign_type(%{changes: %{max_use: _max_use, expire_at: _expire_at}} = changeset) do
  41     put_change(changeset, :invite_type, "reusable_date_limited")
  42   end
  43
  44   defp assign_type(%{changes: %{expire_at: _expire_at}} = changeset) do
  45     put_change(changeset, :invite_type, "date_limited")
  46   end
  47
  48   defp assign_type(%{changes: %{max_use: _max_use}} = changeset) do
  49     put_change(changeset, :invite_type, "reusable")
  50   end
  51
  52   defp assign_type(changeset), do: put_change(changeset, :invite_type, "one_time")
  53
  54   @spec list_invites() :: [UserInviteToken.t()]
  55   def list_invites do
  56     query = from(u in UserInviteToken, order_by: u.id)
  57     Repo.all(query)
  58   end
  59
  60   @spec update_invite!(UserInviteToken.t(), map()) :: UserInviteToken.t() | no_return()
  61   def update_invite!(invite, changes) do
  62     change(invite, changes) |> Repo.update!()
  63   end
  64
  65   @spec update_invite(UserInviteToken.t(), map()) ::
  66           {:ok, UserInviteToken.t()} | {:error, Changeset.t()}
  67   def update_invite(invite, changes) do
  68     change(invite, changes) |> Repo.update()
  69   end
  70
  71   @spec find_by_token!(token()) :: UserInviteToken.t() | no_return()
  72   def find_by_token!(token), do: Repo.get_by!(UserInviteToken, token: token)
  73
  74   @spec valid_invite?(UserInviteToken.t()) :: boolean()
  75   def valid_invite?(%{invite_type: "one_time"} = invite) do
  76     not invite.used
  77   end
  78
  79   def valid_invite?(%{invite_type: "date_limited"} = invite) do
  80     not_overdue_date?(invite) and not invite.used
  81   end
  82
  83   def valid_invite?(%{invite_type: "reusable"} = invite) do
  84     invite.uses < invite.max_use and not invite.used
  85   end
  86
  87   def valid_invite?(%{invite_type: "reusable_date_limited"} = invite) do
  88     not_overdue_date?(invite) and invite.uses < invite.max_use and not invite.used
  89   end
  90
  91   defp not_overdue_date?(%{expire_at: expire_at} = invite) do
  92     Date.compare(Date.utc_today(), expire_at) in [:lt, :eq] ||
  93       (update_invite!(invite, %{used: true}) && false)
  94   end
  95
  96   @spec update_usage!(UserInviteToken.t()) :: nil | UserInviteToken.t() | no_return()
  97   def update_usage!(%{invite_type: "date_limited"}), do: nil
  98
  99   def update_usage!(%{invite_type: "one_time"} = invite),
 100     do: update_invite!(invite, %{used: true})
 101
 102   def update_usage!(%{invite_type: invite_type} = invite)
 103       when invite_type == "reusable" or invite_type == "reusable_date_limited" do
 104     changes = %{
 105       uses: invite.uses + 1
 106     }
 107
 108     changes =
 109       if changes.uses >= invite.max_use do
 110         Map.put(changes, :used, true)
 111       else
 112         changes
 113       end
 114
 115     update_invite!(invite, changes)
 116   end
 117 end